[arch-commits] Commit in tensorflow/repos (2 files)
Sven-Hendrik Haase
svenstaro at archlinux.org
Thu Oct 5 13:43:02 UTC 2017
Date: Thursday, October 5, 2017 @ 13:43:01
Author: svenstaro
Revision: 261694
archrelease: copy trunk to community-testing-x86_64
Added:
tensorflow/repos/community-testing-x86_64/
tensorflow/repos/community-testing-x86_64/PKGBUILD
(from rev 261693, tensorflow/trunk/PKGBUILD)
----------+
PKGBUILD | 125 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 125 insertions(+)
Copied: tensorflow/repos/community-testing-x86_64/PKGBUILD (from rev 261693, tensorflow/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2017-10-05 13:43:01 UTC (rev 261694)
@@ -0,0 +1,125 @@
+# Maintainer: Sven-Hendrik Haase <sh at lutzhaase.com>
+# Contributor: Adria Arrufat (archdria) <adria.arrufat+AUR at protonmail.ch>
+# Contributor: Thibault Lorrain (fredszaq) <fredszaq at gmail.com>
+
+pkgbase=tensorflow
+pkgname=(tensorflow tensorflow-cuda python-tensorflow python-tensorflow-cuda)
+# I went with git for just this release because I couldn't be bothered to
+# backport all the patches needed for bazel 0.6, cuda 9, and cudnn 7.
+pkgver=1.4.0a.git1
+pkgrel=1
+pkgdesc="Library for computation using data flow graphs for scalable machine learning"
+url="https://www.tensorflow.org/"
+license=('Apache2')
+arch=('x86_64')
+makedepends=('git' 'bazel' 'python-numpy' 'gcc6' 'cuda' 'nvidia-utils'
+ 'cudnn' 'python-pip' 'python-wheel' 'python-setuptools')
+optdepends=('tensorboard: Tensorflow visualization toolkit')
+source=("git://github.com/tensorflow/tensorflow.git#commit=64f0ebd")
+sha512sums=('SKIP')
+
+prepare() {
+ cp -r tensorflow tensorflow-${pkgver}
+
+ cp -r tensorflow-${pkgver} tensorflow-${pkgver}-cuda
+ # These environment variables influence the behavior of the configure call below.
+ export TF_NEED_MKL=0
+ export PYTHON_BIN_PATH=/usr/bin/python
+ export USE_DEFAULT_PYTHON_LIB_PATH=1
+ export CC_OPT_FLAGS="-march=x86-64"
+ export TF_NEED_JEMALLOC=1
+ export TF_NEED_GCP=0
+ export TF_NEED_HDFS=0
+ export TF_ENABLE_XLA=1
+ export TF_NEED_GDR=0
+ export TF_NEED_VERBS=0
+ export TF_NEED_OPENCL=0
+ export TF_NEED_MPI=0
+}
+
+build() {
+ cd ${srcdir}/tensorflow-${pkgver}
+
+ export TF_NEED_CUDA=0
+
+ ./configure
+ bazel build --config=opt //tensorflow:libtensorflow.so //tensorflow/tools/pip_package:build_pip_package
+ bazel-bin/tensorflow/tools/pip_package/build_pip_package ${srcdir}/tmp
+
+ cd ${srcdir}/tensorflow-${pkgver}-cuda
+
+ export TF_NEED_CUDA=1
+ # For next version instead of the gcc-6 stuff:
+ export GCC_HOST_COMPILER_PATH=/usr/bin/gcc-6
+ export TF_CUDA_CLANG=0
+ # export CLANG_CUDA_COMPILER_PATH=/usr/bin/clang
+ export CUDA_TOOLKIT_PATH=/opt/cuda
+ export TF_CUDA_VERSION=$($CUDA_TOOLKIT_PATH/bin/nvcc --version | sed -n 's/^.*release \(.*\),.*/\1/p')
+ export CUDNN_INSTALL_PATH=/opt/cuda
+ export TF_CUDNN_VERSION=$(sed -n 's/^#define CUDNN_MAJOR\s*\(.*\).*/\1/p' $CUDNN_INSTALL_PATH/include/cudnn.h)
+ export TF_CUDA_COMPUTE_CAPABILITIES=3.0,3.5,5.2,6.1,6.2
+
+ ./configure
+ bazel build --config=opt --config=cuda //tensorflow:libtensorflow.so //tensorflow/tools/pip_package:build_pip_package
+ bazel-bin/tensorflow/tools/pip_package/build_pip_package ${srcdir}/tmpcuda
+}
+
+package_tensorflow() {
+ cd ${srcdir}/tensorflow-${pkgver}
+
+ tensorflow/c/generate-pc.sh --prefix=/usr --version=${pkgver}
+ install -Dm644 tensorflow.pc ${pkgdir}/usr/lib/pkgconfig/tensorflow.pc
+ install -Dm755 bazel-bin/tensorflow/libtensorflow.so ${pkgdir}/usr/lib/libtensorflow.so
+ install -Dm644 tensorflow/c/c_api.h ${pkgdir}/usr/include/tensorflow/c/c_api.h
+ install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
+}
+
+package_tensorflow-cuda() {
+ depends=(cuda cudnn)
+ conflicts=(tensorflow)
+ provides=(tensorflow)
+
+ cd ${srcdir}/tensorflow-${pkgver}-cuda
+
+ tensorflow/c/generate-pc.sh --prefix=/usr --version=${pkgver}
+ install -Dm644 tensorflow.pc ${pkgdir}/usr/lib/pkgconfig/tensorflow.pc
+ install -Dm755 bazel-bin/tensorflow/libtensorflow.so ${pkgdir}/usr/lib/libtensorflow.so
+ install -Dm644 tensorflow/c/c_api.h ${pkgdir}/usr/include/tensorflow/c/c_api.h
+ install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
+}
+
+package_python-tensorflow() {
+ depends=(python python-protobuf)
+
+ cd ${srcdir}/tensorflow-${pkgver}
+
+ WHEEL_PACKAGE=$(find ${srcdir}/tmp -name "tensor*.whl")
+ pip install --ignore-installed --upgrade --root $pkgdir/ $WHEEL_PACKAGE --no-dependencies
+
+ # tensorboard has been separated from upstream but they still install it with
+ # tensorflow. I don't know what kind of sense that makes but we have to clean
+ # it out from this pacakge.
+ rm -rf ${pkgdir}/usr/bin/tensorboard
+
+ install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
+}
+
+package_python-tensorflow-cuda() {
+ depends=(python cuda cudnn python-pycuda python-protobuf)
+ conflicts=(python-tensorflow)
+ provides=(python-tensorflow)
+
+ cd ${srcdir}/tensorflow-${pkgver}-cuda
+
+ WHEEL_PACKAGE=$(find ${srcdir}/tmpcuda -name "tensor*.whl")
+ pip install --ignore-installed --upgrade --root $pkgdir/ $WHEEL_PACKAGE --no-dependencies
+
+ # tensorboard has been separated from upstream but they still install it with
+ # tensorflow. I don't know what kind of sense that makes but we have to clean
+ # it out from this pacakge.
+ rm -rf ${pkgdir}/usr/bin/tensorboard
+
+ install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list