[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, October 6, 2017 @ 06:51:17
  Author: felixonmars
Revision: 261836

addpkg: python-cssselect2 0.2.1-1

Added:
  python-cssselect2/
  python-cssselect2/repos/
  python-cssselect2/trunk/
  python-cssselect2/trunk/PKGBUILD

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Added: python-cssselect2/trunk/PKGBUILD
===================================================================
--- python-cssselect2/trunk/PKGBUILD	                        (rev 0)
+++ python-cssselect2/trunk/PKGBUILD	2017-10-06 06:51:17 UTC (rev 261836)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Simon Sapin <simon dot sapin at exyr dot org>
+# Contributor: Kyle Keen <keenerd at gmail.com>
+
+pkgbase=python-cssselect2
+pkgname=(python-cssselect2 python2-cssselect2)
+pkgver=0.2.1
+pkgrel=1
+pkgdesc="CSS selectors for Python ElementTree"
+url="https://pypi.python.org/pypi/cssselect2"
+license=('BSD')
+arch=('any')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-tinycss2' 'python2-tinycss2')
+checkdepends=('python-pytest-flake8' 'python2-pytest-flake8' 'python-pytest-cov'
+              'python2-pytest-cov' 'python-pytest-isort' 'python2-pytest-isort'
+              'python-pytest-runner' 'python2-pytest-runner')
+source=("https://pypi.io/packages/source/c/cssselect2/cssselect2-$pkgver.tar.gz")
+md5sums=('bfa61b1e917d1e93ebccf0f27903087d')
+
+prepare() {
+  cp -a cssselect2-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/cssselect2-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/cssselect2-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/cssselect2-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/cssselect2-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_python-cssselect2() {
+  depends=('python-tinycss2')
+
+  cd cssselect2-$pkgver
+  python3 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-cssselect2() {
+  depends=('python2-tinycss2')
+
+  cd cssselect2-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}


Property changes on: python-cssselect2/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property