[arch-commits] Commit in (meek meek/repos meek/trunk meek/trunk/PKGBUILD)

[Felix Yan]

    Date: Thursday, October 12, 2017 @ 13:05:32
  Author: felixonmars
Revision: 262438

addpkg: meek 0.28-1

Added:
  meek/
  meek/repos/
  meek/trunk/
  meek/trunk/PKGBUILD

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Added: meek/trunk/PKGBUILD
===================================================================
--- meek/trunk/PKGBUILD	                        (rev 0)
+++ meek/trunk/PKGBUILD	2017-10-12 13:05:32 UTC (rev 262438)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: shyokou <shyokou at gmail dot com>
+# Contributor: N. Izumi aka izmntuk
+
+pkgname=meek
+pkgver=0.28
+pkgrel=1
+arch=('i686' 'x86_64')
+pkgdesc='A pluggable transport proxy written in Go'
+optdepends=('tor')
+url='https://trac.torproject.org/projects/tor/wiki/doc/meek'
+license=('custom:CC0')
+depends=('glibc')
+makedepends=('go' 'git')
+source=("git+https://git.torproject.org/pluggable-transports/meek.git#tag=$pkgver")
+sha1sums=('SKIP')
+
+prepare() {
+	cd "$srcdir"/meek
+	sed 's|./meek-client|/usr/bin/meek-client|g;
+	     s|./meek-server|/usr/bin/meek-server|g;
+	     s|\(meek-server\.log\)|/tmp/\1|;
+	     s|\(meek-client\.log\)|/tmp/\1|' -i meek-{server,client}/torrc
+}
+
+build() {
+	export GOPATH="$srcdir"
+	export GOBIN="$PWD"
+
+	cd "$srcdir"/meek/meek-server
+	go get
+	make all
+
+	cd "$srcdir"/meek/meek-client
+	make all
+}
+
+package() {
+	install -d "$pkgdir"/usr/{bin,share/{{doc,licenses}/$pkgname,man/man1}}
+	cd "$srcdir"/meek/meek-server
+	install -m755 meek-server "$pkgdir"/usr/bin
+	install -Dm644 torrc "$pkgdir"/usr/share/doc/$pkgname/torrc.meek-server
+	install -Dm644 README "$pkgdir"/usr/share/doc/$pkgname/README.meek-server
+
+	cd "$srcdir"/meek/meek-client
+	install -m755 meek-client "$pkgdir"/usr/bin
+	install -Dm644 torrc "$pkgdir"/usr/share/doc/$pkgname/torrc.meek-client
+	install -m644 ../README "$pkgdir"/usr/share/doc/$pkgname
+	install -m644 ../COPYING "$pkgdir"/usr/share/licenses/$pkgname
+	install -m644 ../doc/meek-{server,client}.1 "$pkgdir"/usr/share/man/man1
+}


Property changes on: meek/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property