[arch-commits] Commit in (wimlib wimlib/repos wimlib/trunk wimlib/trunk/PKGBUILD)

[Alad Wenter]

    Date: Thursday, October 12, 2017 @ 13:57:13
  Author: alad
Revision: 262459

Added to community

Added:
  wimlib/
  wimlib/repos/
  wimlib/trunk/
  wimlib/trunk/PKGBUILD

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Added: wimlib/trunk/PKGBUILD
===================================================================
--- wimlib/trunk/PKGBUILD	                        (rev 0)
+++ wimlib/trunk/PKGBUILD	2017-10-12 13:57:13 UTC (rev 262459)
@@ -0,0 +1,36 @@
+# Maintainer: Alad Wenter <alad at mailbox.org>
+# Contributor: Eric Biggers <ebiggers3 at gmail dot com>
+
+pkgname=wimlib
+pkgver=1.11.0
+pkgrel=3
+pkgdesc='A library and program to extract, create, and modify WIM files'
+arch=('i686' 'x86_64')
+url='https://wimlib.net'
+license=('custom')
+depends=('openssl' 'fuse' 'libxml2' 'ntfs-3g')
+checkdepends=('attr')
+optdepends=('cdrkit: for making ISO image of Windows PE'
+            'mtools: for making disk image of Windows PE' 
+            'syslinux: for making disk image of Windows PE'
+            'cabextract: for extracting Windows PE from the WAIK')
+source=("https://wimlib.net/downloads/$pkgname-$pkgver.tar.gz")
+sha256sums=('16d19c3fbbda1c3ac8034b0884f42962e70ec0608ac54defc60f84328ae447a0')
+
+build() {
+    cd "$pkgname-$pkgver"
+    ./configure --with-libcrypto --with-fuse --with-ntfs-3g --prefix=/usr
+    make
+}
+
+check() {
+    cd "$pkgname-$pkgver"
+    make check
+}
+
+package() {
+    cd "$pkgname-$pkgver"
+    make DESTDIR="$pkgdir" install
+    install -Dm644 NEWS README -t "$pkgdir/usr/share/doc/$pkgname"
+    install -Dm644 COPYING* -t "$pkgdir/usr/share/licenses/$pkgname"
+}


Property changes on: wimlib/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property