[arch-commits] Commit in python-evdev/trunk (PKGBUILD)

[Jan Steffens]

    Date: Thursday, October 19, 2017 @ 08:52:34
  Author: heftig
Revision: 308248

0.7.0-1

Added:
  python-evdev/trunk/PKGBUILD

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Added: PKGBUILD
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2017-10-19 08:52:34 UTC (rev 308248)
@@ -0,0 +1,49 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgbase=python-evdev
+pkgname=(python-evdev python2-evdev)
+pkgver=0.7.0
+pkgrel=1
+pkgdesc="Python bindings for the Linux input subsystem"
+arch=(i686 x86_64)
+url="https://python-evdev.readthedocs.io/en/latest/"
+license=(BSD)
+makedepends=(python python2 git)
+_commit=36dda463c1777cea8521317b19a9283431a77a32  # tags/v0.7.0
+source=("$pkgbase::git+https://github.com/gvalkov/python-evdev#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  cp -a $pkgbase python2
+  cp -a $pkgbase python3
+}
+
+build() {
+  cd python3
+  python3 setup.py build
+
+  cd ../python2
+  python2 setup.py build
+}
+
+package_python-evdev() {
+  depends=(python)
+
+  cd python3
+  python3 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dt "$pkgdir/usr/share/licenses/python-evdev" -m644 LICENSE
+}
+
+package_python2-evdev() {
+  depends=(python2)
+
+  cd python2
+  python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dt "$pkgdir/usr/share/licenses/python2-evdev" -m644 LICENSE
+}


Property changes on: python-evdev/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property