[arch-commits] Commit in flake8/repos (2 files)

[Felix Yan]

    Date: Monday, October 23, 2017 @ 20:44:01
  Author: felixonmars
Revision: 264081

archrelease: copy trunk to community-testing-any

Added:
  flake8/repos/community-testing-any/
  flake8/repos/community-testing-any/PKGBUILD
    (from rev 264080, flake8/trunk/PKGBUILD)

----------+
 PKGBUILD |   68 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)

Copied: flake8/repos/community-testing-any/PKGBUILD (from rev 264080, flake8/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD	                        (rev 0)
+++ community-testing-any/PKGBUILD	2017-10-23 20:44:01 UTC (rev 264081)
@@ -0,0 +1,68 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Karol "Kenji Takahashi" Woźniak <kenji.sx>
+# Contributor: spider-mario <spidermario at free.fr>
+# Contributor: Allen Li <darkfeline at abagofapples.com>
+
+pkgbase=flake8
+pkgname=(flake8 python2-flake8)
+pkgver=3.5.0
+pkgrel=1
+epoch=1
+pkgdesc="The modular source code checker: pep8, pyflakes and co"
+arch=('any')
+url="http://flake8.pycqa.org"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-pyflakes' 'python2-pyflakes'
+             'python-pycodestyle' 'python2-pycodestyle' 'python-mccabe' 'python2-mccabe'
+             'python2-enum34' 'python2-configparser' 'python-pytest-runner' 'python2-pytest-runner')
+checkdepends=('python-mock' 'python2-mock')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/PyCQA/flake8/archive/$pkgver.tar.gz")
+sha512sums=('36c6bd0166a0e8f9b8c99cfd7d92f21a4b8d761727185bbd0dff231001dbb495ed4128e2c60ab16bf3920a8a8394efb0127d9233962940333cfc346766736639')
+
+prepare() {
+  sed -i -e 's/, *< *[0-9=.]*//' flake8-$pkgver/setup.py
+  cp -a flake8-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/flake8-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/flake8-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/flake8-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/flake8-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_flake8() {
+  depends=('python-pyflakes' 'python-mccabe' 'python-pycodestyle')
+  provides=('flake8-python3')
+  replaces=('flake8-python3')
+  conflicts=('flake8-python3')
+
+  cd "$srcdir"/flake8-$pkgver
+  python setup.py install --root="$pkgdir" --prefix=/usr --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-flake8() {
+  depends=('python2-pyflakes' 'python2-mccabe' 'python2-pycodestyle' 'python2-enum34'
+           'python2-configparser')
+  provides=('flake8-python2')
+  replaces=('flake8-python2')
+  conflicts=('flake8-python2')
+
+  cd "$srcdir"/flake8-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --prefix=/usr --optimize=1
+  mv "$pkgdir"/usr/bin/flake8{,-python2}
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+# vim:set ts=2 sw=2 et: