[arch-commits] Commit in flatpak-builder/trunk (PKGBUILD)

[Jan Steffens]

    Date: Tuesday, September 5, 2017 @ 20:09:27
  Author: heftig
Revision: 304716

0.9.9-1

Added:
  flatpak-builder/trunk/PKGBUILD

----------+
 PKGBUILD |   65 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

Added: PKGBUILD
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2017-09-05 20:09:27 UTC (rev 304716)
@@ -0,0 +1,65 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=flatpak-builder
+pkgver=0.9.9
+pkgrel=1
+pkgdesc="Tool to build flatpaks from source"
+url="http://flatpak.org"
+arch=(i686 x86_64)
+license=(LGPL2.1)
+depends=(flatpak binutils elfutils unzip tar git bzr patch rpmextract cpio appstream-glib)
+makedepends=(intltool gobject-introspection git docbook-xsl xmlto libdwarf)
+checkdepends=(python2 valgrind)
+replaces=('flatpak<0.9.10')
+_commit=bf876b2e47cc88fb47d0ad33451465e04fff20b1  # tags/0.9.9
+source=("git+https://github.com/flatpak/flatpak-builder#commit=$_commit"
+        "git+https://git.gnome.org/browse/libglnx")
+sha256sums=('SKIP'
+            'SKIP')
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.libglnx.url "$srcdir/libglnx"
+  git submodule update
+
+  # https://github.com/flatpak/flatpak/issues/267
+  sed -i '/locale\/C\./d' tests/make-test-runtime.sh
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+build() {
+  cd $pkgname
+
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --sbindir=/usr/bin \
+    --libexecdir=/usr/lib/$pkgname \
+    --disable-static \
+    --with-dwarf-header=/usr/include/libdwarf
+
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+check() {
+  cd $pkgname
+  # Xattr tests fail on tmpfs
+  make -k check || :
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}


Property changes on: flatpak-builder/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property