[arch-commits] Commit in gnome-shell-extensions/repos (2 files)

[Jan Steffens]

    Date: Wednesday, September 20, 2017 @ 20:07:59
  Author: heftig
Revision: 305981

archrelease: copy trunk to gnome-unstable-any

Added:
  gnome-shell-extensions/repos/gnome-unstable-any/
  gnome-shell-extensions/repos/gnome-unstable-any/PKGBUILD
    (from rev 305980, gnome-shell-extensions/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: gnome-shell-extensions/repos/gnome-unstable-any/PKGBUILD (from rev 305980, gnome-shell-extensions/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-any/PKGBUILD	                        (rev 0)
+++ gnome-unstable-any/PKGBUILD	2017-09-20 20:07:59 UTC (rev 305981)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gnome-shell-extensions
+pkgver=3.26.0+4+gf4510b9
+pkgrel=1
+pkgdesc="Extensions for GNOME shell, including classic mode"
+url="https://wiki.gnome.org/Projects/GnomeShell/Extensions"
+arch=(any)
+license=(GPL)
+depends=(gnome-shell)
+makedepends=(intltool git gnome-common)
+optdepends=('nautilus: gnome-classic session')
+groups=(gnome)
+_commit=f4510b9b045aad1f27fa97bef04140d8569d1492  # master
+source=("git+https://git.gnome.org/browse/gnome-shell-extensions#commit=$_commit"
+        "git+https://git.gnome.org/browse/gnome-shell-sass")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.data/gnome-shell-sass.url "$srcdir/gnome-shell-sass"
+  git submodule update
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --libexecdir=/usr/lib/gnome-session --enable-extensions=all
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}