[arch-commits] Commit in hledger-web/repos (2 files)

[Felix Yan]

    Date: Wednesday, April 4, 2018 @ 15:21:42
  Author: felixonmars
Revision: 314154

archrelease: copy trunk to community-staging-x86_64

Added:
  hledger-web/repos/community-staging-x86_64/
  hledger-web/repos/community-staging-x86_64/PKGBUILD
    (from rev 314153, hledger-web/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: hledger-web/repos/community-staging-x86_64/PKGBUILD (from rev 314153, hledger-web/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-04-04 15:21:42 UTC (rev 314154)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=hledger-web
+pkgver=1.9
+pkgrel=1
+pkgdesc="Web interface for the hledger accounting tool"
+url="http://hledger.org"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'hledger' 'haskell-hledger-lib' 'haskell-base-compat' 'haskell-blaze-html'
+         'haskell-blaze-markup' 'haskell-clientsession' 'haskell-cmdargs' 'haskell-data-default'
+         'haskell-hjsmin' 'haskell-http-conduit' 'haskell-http-client' 'haskell-hunit'
+         'haskell-conduit-extra' 'haskell-safe' 'haskell-shakespeare' 'haskell-text' 'haskell-wai'
+         'haskell-wai-extra' 'haskell-wai-handler-launch' 'haskell-warp' 'haskell-yesod'
+         'haskell-yesod-core' 'haskell-yesod-form' 'haskell-yesod-static' 'haskell-json'
+         'haskell-megaparsec' 'haskell-mtl' 'haskell-parsec')
+makedepends=('ghc' 'haskell-hspec' 'haskell-yesod-test')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz"
+        https://github.com/simonmichael/hledger/commit/98647ee6f2b01736290ff3f16398aab03b424e49.patch)
+sha512sums=('38feb7e002b72dd91b22819f504dcedb0e7b2700268ccfc8c71dde267247218ac5b83c118aa61d3b5a973af7550c72bffbe976a930f64a2996ef0f08e23d9c5b'
+            '7e31c53265f7939141a4749f48e2c698ae83e94a3b356fed44d02e1262168ffbc0b9d9715c412b1f1284fc72a594765aa19868b1885a6308f3c14afa7c36baf8')
+
+prepare() {
+    cd $pkgname-$pkgver
+    patch -p2 -i ../98647ee6f2b01736290ff3f16398aab03b424e49.patch
+}
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-dev -f-library-only -fthreaded
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}