[arch-commits] Commit in (sndio sndio/repos sndio/trunk sndio/trunk/PKGBUILD)

Ivy Foster escondida at archlinux.org
Wed Apr 4 22:07:28 UTC 2018


    Date: Wednesday, April 4, 2018 @ 22:07:27
  Author: escondida
Revision: 314291

Add sndio-1.4.0-1

Added:
  sndio/
  sndio/repos/
  sndio/trunk/
  sndio/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: sndio/trunk/PKGBUILD
===================================================================
--- sndio/trunk/PKGBUILD	                        (rev 0)
+++ sndio/trunk/PKGBUILD	2018-04-04 22:07:27 UTC (rev 314291)
@@ -0,0 +1,42 @@
+# Maintainer: Ivy Foster <code at escondida.tk>
+# Reference: PKGBUILD(5)
+
+pkgname=sndio
+pkgver=1.4.0
+pkgrel=1
+pkgdesc='A small audio and MIDI framework part of the OpenBSD project'
+arch=(x86_64)
+url='http://www.sndio.org'
+license=(ISC)
+
+# sndio can be built without libbsd, but there are a bunch of individual
+# ISC-licensed files by different authors to extract the licenses from
+# if done that way. Licenses are complicated.
+depends=(alsa-lib libbsd)
+
+source=("http://www.sndio.org/sndio-$pkgver.tar.gz")
+# checksums provided by packager
+sha256sums=(68713db624797dbff69c0f4ce1b24054fb0803da340508edbc5e08d6778f9781)
+backup=(etc/default/sndiod)
+
+build() {
+	cd "sndio-$pkgver"
+	./configure --prefix=/usr --enable-alsa --with-libbsd
+	make
+}
+
+package() {
+	cd "sndio-$pkgver"
+
+	make DESTDIR="$pkgdir/" install
+
+	install -D -m 644 contrib/sndiod.service \
+		"$pkgdir/usr/lib/systemd/system/sndiod.service"
+	install -D -m 644 contrib/default.sndiod \
+		"$pkgdir/etc/default/sndiod"
+
+	install -d "$pkgdir/usr/share/licenses/sndio"
+	# this is the most up-to-date license outside of bsd-compat,
+	# which isn't being used in this build
+	sed '/^ \*\//q' aucat/aucat.c > "$pkgdir/usr/share/licenses/sndio/LICENSE"
+}


Property changes on: sndio/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list