[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Sunday, April 8, 2018 @ 04:49:19
  Author: felixonmars
Revision: 314922

addpkg: haskell-dbus0.10 0.10.15-1

Added:
  haskell-dbus0.10/
  haskell-dbus0.10/repos/
  haskell-dbus0.10/trunk/
  haskell-dbus0.10/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: haskell-dbus0.10/trunk/PKGBUILD
===================================================================
--- haskell-dbus0.10/trunk/PKGBUILD	                        (rev 0)
+++ haskell-dbus0.10/trunk/PKGBUILD	2018-04-08 04:49:19 UTC (rev 314922)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=dbus
+pkgname=haskell-dbus0.10
+pkgver=0.10.15
+pkgrel=1
+pkgdesc="A client library for the D-Bus IPC system (legacy 0.10.x version)"
+url="https://john-millikin.com/software/haskell-dbus/"
+license=("GPL3")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-cereal' 'haskell-libxml-sax' 'haskell-network' 'haskell-parsec'
+         'haskell-random' 'haskell-text' 'haskell-vector' 'haskell-xml-types')
+makedepends=('ghc' 'haskell-extra' 'haskell-quickcheck' 'haskell-resourcet' 'haskell-tasty'
+             'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('5c81c1f8599b80cdb16bee63b97cd1aa5d6b0698095b2c366ad4e4f03b44f9166bd5d770f8a47a0c7dd746a9a734379dc20a77f7846a862bd1c213eb12559b0b')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/license.txt"
+}


Property changes on: haskell-dbus0.10/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property