[arch-commits] Commit in gobject-introspection/repos (2 files)

[Jan Steffens]

    Date: Monday, April 9, 2018 @ 06:30:13
  Author: heftig
Revision: 321334

archrelease: copy trunk to testing-x86_64

Added:
  gobject-introspection/repos/testing-x86_64/
  gobject-introspection/repos/testing-x86_64/PKGBUILD
    (from rev 321333, gobject-introspection/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: gobject-introspection/repos/testing-x86_64/PKGBUILD (from rev 321333, gobject-introspection/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2018-04-09 06:30:13 UTC (rev 321334)
@@ -0,0 +1,49 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=gobject-introspection
+pkgname=(gobject-introspection gobject-introspection-runtime)
+pkgver=1.56.1
+pkgrel=1
+pkgdesc="Introspection system for GObject-based libraries"
+url="https://wiki.gnome.org/Projects/GObjectIntrospection"
+arch=(x86_64)
+license=(LGPL GPL)
+depends=(python python-mako)
+makedepends=(cairo git gtk-doc)
+options=(!emptydirs)
+_commit=14ff69f032c603e6100728088ebbda19fd44db8a  # tags/1.56.1^0
+source=("git+https://gitlab.gnome.org/GNOME/gobject-introspection.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+  NOCONFIGURE=1 ./autogen.sh
+}
+  
+build() {
+  cd $pkgbase
+  ./configure --prefix=/usr --disable-static --enable-doctool --enable-gtk-doc
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package_gobject-introspection-runtime() {
+  pkgdesc+=" (runtime library)"
+  depends=(glib2)
+  cd $pkgbase
+  make DESTDIR="$pkgdir" install-libLTLIBRARIES install-typelibsDATA
+}
+
+package_gobject-introspection() {
+  depends+=("gobject-introspection-runtime=$pkgver-$pkgrel")
+
+  cd $pkgbase
+  make DESTDIR="$pkgdir" install
+  make DESTDIR="$pkgdir" uninstall-libLTLIBRARIES uninstall-typelibsDATA
+}