[arch-commits] Commit in srt/repos/extra-x86_64 (PKGBUILD PKGBUILD no-rpath.diff)

[Jan Steffens]

    Date: Wednesday, April 11, 2018 @ 15:58:25
  Author: heftig
Revision: 321559

archrelease: copy trunk to extra-x86_64

Added:
  srt/repos/extra-x86_64/PKGBUILD
    (from rev 321558, srt/trunk/PKGBUILD)
  srt/repos/extra-x86_64/no-rpath.diff
    (from rev 321558, srt/trunk/no-rpath.diff)
Deleted:
  srt/repos/extra-x86_64/PKGBUILD

---------------+
 PKGBUILD      |  100 +++++++++++++++++++++++++++++++-------------------------
 no-rpath.diff |   12 ++++++
 2 files changed, 69 insertions(+), 43 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2018-04-11 15:57:53 UTC (rev 321558)
+++ PKGBUILD	2018-04-11 15:58:25 UTC (rev 321559)
@@ -1,43 +0,0 @@
-# $Id$
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-
-pkgname=srt
-pkgver=1.2.3
-pkgrel=1
-pkgdesc="Secure Reliable Transport library"
-url="https://www.srtalliance.org/"
-arch=(x86_64)
-license=(MPL2)
-depends=(openssl)
-makedepends=(git cmake ninja)
-_commit=1367914ea5d7e26be8274e2fffe8b3e7b05ad193  # tags/v1.2.3
-source=("git+https://github.com/Haivision/srt#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/^v//;s/-/+/g'
-}
-
-prepare() {
-  mkdir build
-}
-
-build() {
-  cd build
-  cmake -G Ninja ../srt \
-    -DCMAKE_INSTALL_PREFIX=/usr
-  ninja
-}
-
-check() {
-  cd build
-  ./utility-test
-}
-
-package() {
-  DESTDIR="$pkgdir" ninja -C build install
-}
-# vim:set ts=2 sw=2:
-
-

Copied: srt/repos/extra-x86_64/PKGBUILD (from rev 321558, srt/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2018-04-11 15:58:25 UTC (rev 321559)
@@ -0,0 +1,57 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=srt
+pkgver=1.3.0
+pkgrel=1
+pkgdesc="Secure Reliable Transport library"
+url="https://www.srtalliance.org/"
+arch=(x86_64)
+license=(MPL2)
+depends=(openssl)
+makedepends=(git cmake ninja)
+_commit=52769952acb191a90a3b6a0523cae99791e91df8  # tags/v1.3.0
+source=("git+https://github.com/Haivision/srt#commit=$_commit"
+        no-rpath.diff)
+sha256sums=('SKIP'
+            'ce9a97d661d796da85a7e4faf9c70c27368d00eb505f85c03a31bba8f22e6847')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  mkdir build
+  cd $pkgname
+  patch -Np1 -i ../no-rpath.diff
+}
+
+build() {
+  cd build
+  cmake -G Ninja ../srt \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_BINDIR=bin \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_INSTALL_INCLUDEDIR=include \
+    -DENABLE_TESTING=True
+  cmake --build .
+}
+
+check() {
+  cd build
+  ./utility-test
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --build build --target install
+  rm "$pkgdir"/usr/bin/*-test
+
+  # Build tries this but fails when DESTDIR is set
+  ln -s srt-live-transmit "$pkgdir/usr/bin/stransmit"
+
+  ln -s srt-ffplay "$pkgdir/usr/bin/sfplay"
+}
+# vim:set ts=2 sw=2:
+
+

Copied: srt/repos/extra-x86_64/no-rpath.diff (from rev 321558, srt/trunk/no-rpath.diff)
===================================================================
--- no-rpath.diff	                        (rev 0)
+++ no-rpath.diff	2018-04-11 15:58:25 UTC (rev 321559)
@@ -0,0 +1,12 @@
+diff --git i/CMakeLists.txt w/CMakeLists.txt
+index e913122..2cc3c3d 100644
+--- i/CMakeLists.txt
++++ w/CMakeLists.txt
+@@ -634,7 +634,6 @@ macro(srt_make_application name)
+ 		# be placed into the binrary directory anyway.
+ 		# XXX not sure about Mac.
+ 		# See this name used already in install(${TARGET_srt} LIBRARY DESTINATION...).
+-		set(FORCE_RPATH LINK_FLAGS -Wl,-rpath,.,-rpath,../${CMAKE_INSTALL_LIBDIR} BUILD_WITH_INSTALL_RPATH TRUE INSTALL_RPATH_USE_LINK_PATH TRUE)
+ 	endif()
+ 
+ 	# We state that Darwin always uses CLANG compiler, which honors this flag the same way.