[arch-commits] Commit in (din din/repos din/trunk din/trunk/PKGBUILD)

[David Runge]

    Date: Friday, April 13, 2018 @ 23:00:05
  Author: dvzrv
Revision: 316220

Adding din 32 from AUR.

Added:
  din/
  din/repos/
  din/trunk/
  din/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: din/trunk/PKGBUILD
===================================================================
--- din/trunk/PKGBUILD	                        (rev 0)
+++ din/trunk/PKGBUILD	2018-04-13 23:00:05 UTC (rev 316220)
@@ -0,0 +1,44 @@
+# Maintainer: David Runge <dave at sleepmap.de>
+# Contributor: muzhed <chustokes at 126.com>
+
+pkgname=din
+pkgver=32
+pkgrel=2
+pkgdesc="A sound synthesizer and musical instrument."
+arch=('x86_64')
+url="https://dinisnoise.org/"
+license=('GPL2')
+depends=('jack' 'libgl' 'sdl' 'tcl')
+makedepends=('boost' 'gendesk' 'glu')
+source=("https://archive.org/download/dinisnoise_source_code/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('51eed3846b8ea0784777b9b382aedbe649923b874244297cf4fac244ed6a702964de66e6cb5b1d705f6695897c295542e15cf084f7f8d8350b03c784cf883958')
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+  autoreconf -vfi
+  # XDG desktop file
+  gendesk -n \
+          --pkgname ${pkgname} \
+          --pkgdesc "${pkgdesc}" \
+          --name DIN Is Noise \
+          --categories "Application;AudioVideo;Audio;Midi;Music"
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  CXXFLAGS="${CXXFLAGS} -O3 -D__UNIX_ALSA__ -D__UNIX_JACK__" \
+  CFLAGS="${CFLAGS} -O3" \
+  ./configure --prefix='/usr'
+  make
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  make install DESTDIR="${pkgdir}"
+  # desktop file
+  install -vDm 644 "${pkgname}.desktop" \
+    "${pkgdir}/usr/share/applications/${pkgname}.desktop"
+  # docs
+  install -t "${pkgdir}/usr/share/doc/${pkgname}/" \
+    -vDm 644 {AUTHORS,BUGS,CHANGELOG,NEWS,README,TODO}
+}


Property changes on: din/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property