[arch-commits] Commit in (3 files)

Balló György bgyorgy at archlinux.org
Mon Apr 16 13:21:27 UTC 2018


    Date: Monday, April 16, 2018 @ 13:21:26
  Author: bgyorgy
Revision: 316505

Add gtksourceview4

Needed for tepl 4.0 and gnome-latex 3.28.0

Added:
  gtksourceview4/
  gtksourceview4/trunk/
  gtksourceview4/trunk/PKGBUILD

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Added: gtksourceview4/trunk/PKGBUILD
===================================================================
--- gtksourceview4/trunk/PKGBUILD	                        (rev 0)
+++ gtksourceview4/trunk/PKGBUILD	2018-04-16 13:21:26 UTC (rev 316505)
@@ -0,0 +1,41 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=gtksourceview4
+pkgver=4.0.0
+pkgrel=1
+pkgdesc="A text widget adding syntax highlighting and more to GNOME"
+url="https://wiki.gnome.org/Projects/GtkSourceView"
+arch=(x86_64)
+license=(GPL)
+depends=(gtk3 libxml2)
+makedepends=(intltool gobject-introspection glade vala gtk-doc autoconf-archive git)
+_commit=95be808cab52c8ae9dbf0a4a64a80d1b3cb2e00d  # tags/4.0.0^0
+source=("git+https://git.gnome.org/browse/gtksourceview#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd gtksourceview
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd gtksourceview
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd gtksourceview
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var --disable-static \
+      --enable-glade-catalog --enable-gtk-doc --disable-Werror
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd gtksourceview
+  make DESTDIR="$pkgdir" install
+}


Property changes on: gtksourceview4/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list