[arch-commits] Commit in (gnome-usage gnome-usage/trunk gnome-usage/trunk/PKGBUILD)

[Balló György]

    Date: Monday, April 16, 2018 @ 20:55:33
  Author: bgyorgy
Revision: 316568

Add gnome-usage (part of GNOME)

Added:
  gnome-usage/
  gnome-usage/trunk/
  gnome-usage/trunk/PKGBUILD

----------+
 PKGBUILD |   31 +++++++++++++++++++++++++++++++
 1 file changed, 31 insertions(+)

Added: gnome-usage/trunk/PKGBUILD
===================================================================
--- gnome-usage/trunk/PKGBUILD	                        (rev 0)
+++ gnome-usage/trunk/PKGBUILD	2018-04-16 20:55:33 UTC (rev 316568)
@@ -0,0 +1,31 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=gnome-usage
+pkgver=3.28.0
+pkgrel=1
+pkgdesc="GNOME application to view information about use of system resources"
+arch=(x86_64)
+url="https://wiki.gnome.org/Apps/Usage"
+license=(GPL3)
+depends=(gtk3 libgtop)
+makedepends=(git meson vala)
+optdepends=('accountsservice: show user tags for processes')
+groups=(gnome-extra)
+_commit=b29adffaaf65aa6fcc3d403adbe7999f01157c89  # tags/v3.28.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-usage.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+build() {
+  arch-meson $pkgname build
+  ninja -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" ninja -C build install
+}


Property changes on: gnome-usage/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property