[arch-commits] Commit in qgis (3 files)

[Balló György]

    Date: Tuesday, April 17, 2018 @ 22:19:48
  Author: bgyorgy
Revision: 316833

archrelease: copy trunk to community-x86_64

Added:
  qgis/repos/
  qgis/repos/community-x86_64/
  qgis/repos/community-x86_64/PKGBUILD
    (from rev 316832, qgis/trunk/PKGBUILD)

----------+
 PKGBUILD |   94 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 94 insertions(+)

Copied: qgis/repos/community-x86_64/PKGBUILD (from rev 316832, qgis/trunk/PKGBUILD)
===================================================================
--- repos/community-x86_64/PKGBUILD	                        (rev 0)
+++ repos/community-x86_64/PKGBUILD	2018-04-17 22:19:48 UTC (rev 316833)
@@ -0,0 +1,94 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Doug Newgard <scimmia at archlinux dot org>
+# Contributor: XavierCLL <xavier.corredor.llano (a) gmail.com>
+# Contributor: SaultDon <sault.don gmail>
+# Contributor: Lantald < lantald at gmx.com >
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: dibblethewrecker dibblethewrecker.at.jiwe.dot.org
+# Contributor: Gerardo Exequiel Pozzi <vmlinuz386 at yahoo.com.ar>
+# Contributor: Eric Forgeot < http://esclinux.tk >
+
+pkgname=qgis
+pkgver=3.0.1
+pkgrel=2
+pkgdesc='Geographic Information System (GIS) that supports vector, raster & database formats'
+url='https://qgis.org/'
+license=(GPL)
+arch=(x86_64)
+depends=(gdal hicolor-icon-theme libzip python-qscintilla-qt5 qca-qt5 qextserialport qt5-3d qt5-webkit qtkeychain qwtpolar spatialindex)
+makedepends=(cmake fcgi gsl python-six qt5-tools txt2tags)
+optdepends=('fcgi: Map server'
+            'gpsbabel: GPS Tools plugin'
+            'gsl: Georeferencer plugin'
+            'python-gdal: DB Manager plugin; Processing plugin'
+            'python-jinja: MetaSearch plugin'
+            'python-owslib: MetaSearch plugin'
+            'python-psycopg2: DB Manager plugin; Processing plugin'
+            'python-pygments: MetaSearch plugin'
+            'python-numpy: Processing plugin'
+            'python-yaml: Processing plugin')
+source=("https://qgis.org/downloads/$pkgname-$pkgver.tar.bz2")
+sha256sums=('9e2954597cfbdc82b852281c19d8652265f4785b3cf4d7c05e9a1174a89c44d4')
+
+prepare() {
+  cd $pkgname-$pkgver
+
+  # Find Qt5ExtSerialPort
+  sed -e '/include$/ s/$/\/qt/' \
+      -e 's/qextserialport-1.2/Qt5ExtSerialPort/' \
+      -i cmake/FindQextserialport.cmake
+
+  # Find osgQt
+  sed -e 's/osgQt5 osgQt/osgQt/' \
+      -e 's/osgQt5d osgQtd/osgQt/' \
+      -i src/plugins/globe/CMakeModules/FindOSG.cmake
+
+  # Remove mime types already defined by freedesktop.org
+  sed -e '/type="image\/tiff"/,/<\/mime-type>/d' \
+      -e '/type="image\/jpeg"/,/<\/mime-type>/d' \
+      -e '/type="image\/jp2"/,/<\/mime-type>/d' \
+      -e '/type="application\/x-adobe-mif"/,/<\/mime-type>/d' \
+      -i debian/qgis.xml
+
+  [[ -d build ]] || mkdir build
+}
+
+build() {
+  cd $pkgname-$pkgver/build
+
+  cmake -G "Unix Makefiles" ../ \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DWITH_3D=TRUE \
+    -DWITH_SERVER=TRUE \
+    -DWITH_CUSTOM_WIDGETS=TRUE \
+    -DWITH_INTERNAL_QEXTSERIALPORT=FALSE \
+    -DBINDINGS_GLOBAL_INSTALL=TRUE \
+    -DWITH_PY_COMPILE=TRUE \
+    -DQGIS_MANUAL_SUBDIR=share/man \
+    -DWITH_QWTPOLAR=TRUE \
+    -DWITH_INTERNAL_QWTPOLAR=FALSE
+
+  make
+
+  # Rebuild srs database, QGIS distributes an old, buggy one
+  LD_LIBRARY_PATH="$PWD/output/lib/" make synccrsdb
+  mv /tmp/srs.db ../resources/
+}
+
+package() {
+  cd $pkgname-$pkgver/build
+  make DESTDIR="$pkgdir" install
+
+  cd "$srcdir/$pkgname-$pkgver"
+
+  # install desktop file and icon
+  install -Dm644 debian/qgis.desktop "$pkgdir/usr/share/applications/qgis.desktop"
+  install -Dm644 images/icons/qgis_icon.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/qgis.svg"
+
+  # install mime information and icons
+  install -Dm644 debian/qgis.xml -t "$pkgdir/usr/share/mime/packages/"
+  for _type in qgs qlr qml qpt; do
+    install -Dm644 images/icons/qgis_${_type}_icon.svg "$pkgdir/usr/share/icons/hicolor/scalable/mimetypes/qgis-$_type.svg"
+  done
+}