[arch-commits] Commit in (gpxsee gpxsee/trunk gpxsee/trunk/PKGBUILD)

[Balló György]

    Date: Wednesday, April 18, 2018 @ 06:42:32
  Author: bgyorgy
Revision: 316845

Move gpxsee from AUR

Added:
  gpxsee/
  gpxsee/trunk/
  gpxsee/trunk/PKGBUILD

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Added: gpxsee/trunk/PKGBUILD
===================================================================
--- gpxsee/trunk/PKGBUILD	                        (rev 0)
+++ gpxsee/trunk/PKGBUILD	2018-04-18 06:42:32 UTC (rev 316845)
@@ -0,0 +1,38 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Raffaele Zamorano
+# Contributor: Jose Riha <jose1711 gmail com>
+# Contributor: Nikolay Korotkiy <sikmir at gmail.com>
+
+pkgname=gpxsee
+_pkgname=GPXSee
+pkgver=5.8
+pkgrel=1
+pkgdesc='GPS log file viewer and analyzer'
+arch=(x86_64)
+url='http://www.gpxsee.org/'
+license=(GPL3)
+depends=(qt5-imageformats)
+makedepends=(qt5-tools)
+source=(https://downloads.sourceforge.net/$pkgname/$_pkgname-$pkgver.tar.gz)
+sha256sums=('3ebf8b7b1975d62d2c6f234e3b6a9012cb733e0637d3121a6f83fc9936778022')
+
+build() {
+  cd $_pkgname-$pkgver
+  lrelease-qt5 gpxsee.pro
+  qmake gpxsee.pro
+  make
+}
+
+package() {
+  cd $_pkgname-$pkgver
+  install -dm755 "$pkgdir"/usr/share/$pkgname/{csv,maps,translations}
+  install -Dm755 GPXSee "$pkgdir"/usr/bin/$pkgname
+  install -Dm644 pkg/csv/* "$pkgdir"/usr/share/$pkgname/csv
+  install -Dm644 pkg/maps/* "$pkgdir"/usr/share/$pkgname/maps
+  install -Dm644 lang/*.qm "$pkgdir"/usr/share/$pkgname/translations
+  install -Dm644 icons/gpxsee.png "$pkgdir"/usr/share/pixmaps/$pkgname.png
+  install -Dm644 pkg/gpxsee.desktop "$pkgdir"/usr/share/applications/$pkgname.desktop
+  install -Dm644 pkg/gpxsee.xml "$pkgdir"/usr/share/mime/packages/$pkgname.xml
+  install -Dm644 pkg/appdata.xml "$pkgdir"/usr/share/metainfo/$pkgname.appdata.xml
+}


Property changes on: gpxsee/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property