[arch-commits] Commit in (6 files)
Balló György
bgyorgy at archlinux.org
Thu Apr 19 11:27:04 UTC 2018
Date: Thursday, April 19, 2018 @ 11:27:03
Author: bgyorgy
Revision: 317002
Move back gnucash from AUR with 120 votes
It's ported to GTK+ 3.
Added:
gnucash-docs/
gnucash-docs/trunk/
gnucash-docs/trunk/PKGBUILD
gnucash/
gnucash/trunk/
gnucash/trunk/PKGBUILD
-----------------------------+
gnucash-docs/trunk/PKGBUILD | 25 +++++++++++++++++++++++
gnucash/trunk/PKGBUILD | 44 ++++++++++++++++++++++++++++++++++++++++++
2 files changed, 69 insertions(+)
Added: gnucash/trunk/PKGBUILD
===================================================================
--- gnucash/trunk/PKGBUILD (rev 0)
+++ gnucash/trunk/PKGBUILD 2018-04-19 11:27:03 UTC (rev 317002)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Juergen Hoetzel <juergen at archlinux.org>
+# Contributor: Mark Schneider <queueRAM at gmail.com>
+
+pkgname=gnucash
+pkgver=3.0
+pkgrel=5
+pkgdesc='Personal and small-business financial-accounting application'
+arch=(x86_64)
+url='https://gnucash.org/'
+license=(GPL)
+depends=(aqbanking boost-libs guile libdbi webkit2gtk)
+makedepends=(boost cmake gmock libdbi-drivers libmariadbclient postgresql-libs)
+optdepends=('gnucash-docs: documentation'
+ 'perl-date-manip: stock information lookups'
+ 'perl-finance-quote: stock information lookups')
+options=(!emptydirs)
+source=(https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz)
+sha256sums=('a2dd7be61d4795717295b7629f35df72161a882fd1668dc744a299f63735ba23')
+
+build() {
+ cd $pkgname-$pkgver
+ cmake -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=/usr/lib \
+ -DHAVE_GWEN_GTK3=ON \
+ -DCOMPILE_GSCHEMAS=OFF
+ make
+}
+
+check() {
+ cd $pkgname-$pkgver
+ make -k check || : # 2 tests failed
+}
+
+package() {
+ cd $pkgname-$pkgver
+ make DESTDIR="$pkgdir" install
+
+ # Delete the gnucash-valgrind executable because the source files
+ # are not included with the package and the executable is hardlinked
+ # to the location that it was built at.
+ rm -f "$pkgdir/usr/bin/gnucash-valgrind"
+}
Property changes on: gnucash/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: gnucash-docs/trunk/PKGBUILD
===================================================================
--- gnucash-docs/trunk/PKGBUILD (rev 0)
+++ gnucash-docs/trunk/PKGBUILD 2018-04-19 11:27:03 UTC (rev 317002)
@@ -0,0 +1,25 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Juergen Hoetzel <juergen at archlinux.org>
+
+pkgname=gnucash-docs
+pkgver=3.0
+pkgrel=2
+pkgdesc='Documentation for GnuCash'
+arch=(any)
+url='https://gnucash.org/docs.phtml'
+license=(FDL)
+depends=(yelp)
+source=(https://downloads.sourceforge.net/gnucash/$pkgname-$pkgver.tar.gz)
+sha256sums=('05f662b0318b9415fd87bb5e37b9f44db6c9120f2d602b5ce38db7f1872e067b')
+
+build() {
+ cd $pkgname-$pkgver
+ ./configure --prefix=/usr
+ make
+}
+
+package() {
+ cd $pkgname-$pkgver
+ make DESTDIR="$pkgdir" install
+}
Property changes on: gnucash-docs/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list