[arch-commits] Commit in (4 files)

[Giancarlo Razzolini]

    Date: Friday, April 20, 2018 @ 14:05:17
  Author: grazzolini
Revision: 317208

newpkg: python-lz4

Added:
  python-lz4/
  python-lz4/repos/
  python-lz4/trunk/
  python-lz4/trunk/PKGBUILD

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Added: python-lz4/trunk/PKGBUILD
===================================================================
--- python-lz4/trunk/PKGBUILD	                        (rev 0)
+++ python-lz4/trunk/PKGBUILD	2018-04-20 14:05:17 UTC (rev 317208)
@@ -0,0 +1,54 @@
+# Maintainer: Giancarlo Razzolini <grazzolini at archlinux.org>
+# Contributor: Nissar Chababy <funilrys at outlook dot com>
+# Contributor: Thrasibule <guillaume dot horel at gmail dot com>
+# Contributor: David Manouchehri <manouchehri at riseup.net>
+# Contributor: Vladimir Tsanev <tsachev at gmail.com>
+# Contributor: Andrew Reed <reed.996 at osu.edu>
+# Contributor: "Score_Under" <seejay.11 at gmail.com>
+
+pkgbase=lz4
+pkgname=('python-lz4' 'python2-lz4')
+pkgver=1.1.0
+pkgrel=1
+pkgdesc="LZ4 bindings for Python"
+arch=('x86_64')
+license=('BSD')
+url="https://github.com/python-lz4/python-lz4"
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest' 'python2-pytest')
+source=("https://pypi.org/packages/source/${pkgbase:0:1}/$pkgbase/$pkgbase-${pkgver}.tar.gz")
+sha512sums=('3119247e4334b0898b6258a286ea1e2ffeb2e6da958366ec9aefd48e476f05d16b0f059cf47954ea5efafab5a5de0c3f2a825c9e765b488618d75b2d60726c80')
+
+prepare() {
+  cp -a $pkgbase-${pkgver}{,-python2}
+}
+
+build() {
+  cd "$srcdir"/$pkgbase-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/$pkgbase-$pkgver-python2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/$pkgbase-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/$pkgbase-$pkgver-python2
+  python2 setup.py pytest
+}
+
+package_python-lz4() {
+  depends=('python')
+
+  cd $pkgbase-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}
+
+package_python2-lz4() {
+  depends=('python2')
+
+  cd $pkgbase-$pkgver-python2
+  python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}


Property changes on: python-lz4/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property