[arch-commits] Commit in (9 files)

[Balló György]

    Date: Tuesday, April 24, 2018 @ 08:01:18
  Author: bgyorgy
Revision: 317497

Move gpodder from AUR with 143 votes

Also move its dependencies: python-mygpoclient, python-podcastparser.

Added:
  gpodder/
  gpodder/trunk/
  gpodder/trunk/PKGBUILD
  python-mygpoclient/
  python-mygpoclient/trunk/
  python-mygpoclient/trunk/PKGBUILD
  python-podcastparser/
  python-podcastparser/trunk/
  python-podcastparser/trunk/PKGBUILD

-------------------------------------+
 gpodder/trunk/PKGBUILD              |   25 ++++++++++++++++++++++
 python-mygpoclient/trunk/PKGBUILD   |   37 ++++++++++++++++++++++++++++++++++
 python-podcastparser/trunk/PKGBUILD |   32 +++++++++++++++++++++++++++++
 3 files changed, 94 insertions(+)

Added: gpodder/trunk/PKGBUILD
===================================================================
--- gpodder/trunk/PKGBUILD	                        (rev 0)
+++ gpodder/trunk/PKGBUILD	2018-04-24 08:01:18 UTC (rev 317497)
@@ -0,0 +1,25 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Jan Magnus Brevik <janmbrevik at gmail.com>
+
+pkgname=gpodder
+pkgver=3.10.1
+pkgrel=1
+pkgdesc='Podcast client written in Python using GTK+'
+arch=(any)
+url='https://gpodder.github.io/'
+license=(GPL3)
+depends=(gtk3 python-cairo python-dbus python-gobject python-mygpoclient python-podcastparser)
+makedepends=(intltool)
+source=($pkgname-$pkgver.tar.gz::http://github.com/gpodder/$pkgname/archive/$pkgver.tar.gz)
+sha256sums=('cd3f65146fa202c2861d8f0a2fa212323830c6c437a272f6f88a5e03581e9e0b')
+
+build() {
+  cd $pkgname-$pkgver
+  make messages
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}


Property changes on: gpodder/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: python-mygpoclient/trunk/PKGBUILD
===================================================================
--- python-mygpoclient/trunk/PKGBUILD	                        (rev 0)
+++ python-mygpoclient/trunk/PKGBUILD	2018-04-24 08:01:18 UTC (rev 317497)
@@ -0,0 +1,37 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Muges <git at muges.fr>
+# Contributor: Alexis "Horgix" Chotad <alexis.horgix.chotard at gmail.com>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: Jonas Heinrich <onny at project-insanity.org>
+# Contributor: Markus Golser <elmargol at googlemail.com>
+
+_pkgbase=mygpoclient
+pkgbase=python-$_pkgbase
+pkgname=(python-mygpoclient python2-mygpoclient)
+pkgver=1.8
+pkgrel=1
+pkgdesc='Python client Library for the gpodder.net web service'
+arch=(any)
+url='https://github.com/gpodder/mygpoclient'
+license=(GPL3)
+depends=(python python2)
+source=($pkgbase-$pkgver.tar.gz::https://github.com/gpodder/$_pkgbase/archive/$pkgver.tar.gz)
+sha256sums=('65fcb3ab220a2ba2d32a77f969b423a2f663413b6c485b7b02e5a955b28e68d2')
+
+package_python-mygpoclient() {
+  depends=(python)
+
+  cd $_pkgbase-$pkgver
+  python3 setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-mygpoclient() {
+  depends=(python2)
+
+  cd $_pkgbase-$pkgver
+  python2 setup.py install --root="$pkgdir" --optimize=1
+
+  for file in "$pkgdir"/usr/bin/*; do mv "$file" "${file}2"; done
+  mv "$pkgdir"/usr/share/man/man1/mygpo-bpsync{,2}.1
+}


Property changes on: python-mygpoclient/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: python-podcastparser/trunk/PKGBUILD
===================================================================
--- python-podcastparser/trunk/PKGBUILD	                        (rev 0)
+++ python-podcastparser/trunk/PKGBUILD	2018-04-24 08:01:18 UTC (rev 317497)
@@ -0,0 +1,32 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Jan Magnus Brevik <janmbrevik at gmail.com>
+
+_pkgbase=podcastparser
+pkgbase=python-$_pkgbase
+pkgname=(python-podcastparser python2-podcastparser)
+pkgver=0.6.3
+pkgrel=1
+pkgdesc='Simplified, fast RSS parsing library in Python'
+arch=(any)
+url='https://github.com/gpodder/podcastparser'
+license=(ISC)
+depends=(python python2)
+source=($pkgbase-$pkgver.tar.gz::https://github.com/gpodder/$_pkgbase/archive/$pkgver.tar.gz)
+sha256sums=('5cd36182bf0c8ec5b36fb309b23bb1c67b507909d94ef402f04f08e64e545489')
+
+package_python-podcastparser() {
+  depends=(python)
+
+  cd $_pkgbase-$pkgver
+  python3 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-podcastparser() {
+  depends=(python2)
+
+  cd $_pkgbase-$pkgver
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}


Property changes on: python-podcastparser/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property