[arch-commits] Commit in paraview/repos/community-staging-x86_64 (PKGBUILD)

[Bruno Pagani]

    Date: Tuesday, April 24, 2018 @ 12:14:53
  Author: archange
Revision: 317547

archrelease: copy trunk to community-staging-x86_64

Added:
  paraview/repos/community-staging-x86_64/PKGBUILD
    (from rev 317546, paraview/trunk/PKGBUILD)

----------+
 PKGBUILD |  100 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 100 insertions(+)

Copied: paraview/repos/community-staging-x86_64/PKGBUILD (from rev 317546, paraview/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2018-04-24 12:14:53 UTC (rev 317547)
@@ -0,0 +1,100 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Oliver Goethel <deezy>
+# Contributor: eolianoe eolianoe <eolianoe [at] gmail [DoT] com>
+# Contributor: George Eleftheriou <eleftg>
+# Contributor: Mathias Anselmann <mathias.anselmann at gmail.com>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: Michele Mocciola <mickele>
+# Contributor: Simon Zilliken <simon____AT____zilliken____DOT____name>
+# Contributor: chuckdaniels
+
+_pkg=paraview
+_mpi=openmpi
+pkgname=${_pkg}
+#-${_mpi}
+pkgver=5.5.0
+pkgrel=2
+pkgdesc="Parallel Visualization application using VTK (${_mpi} version)"
+arch=('x86_64')
+url="https://www.paraview.org"
+license=('custom')
+depends=('qt5-tools' 'qt5-x11extras' 'ospray' 'ffmpeg' 'openmpi'
+         'cgns' 'python-pygments' 'protobuf' 'pugixml'
+         'python-matplotlib' 'python-numpy' 'python-mpi4py'
+         'boost-libs' 'glew' 'expat' 'freetype2'
+         'libjpeg' 'jsoncpp' 'libxml2' 'libpng'
+         'libtiff' 'zlib' 'hdf5-openmpi' 'lz4' 'netcdf')
+#        netcdf-cxx gl2ps libharu
+#        python-txaio python-hyperlink
+#        proj apparently not used in this VTK configuration
+makedepends=('cmake' 'boost' 'mesa' 'gcc-fortran' 'ninja' 'qt5-tools' 'qt5-xmlpatterns')
+source=("${url}/files/v${pkgver:0:3}/ParaView-v${pkgver}.tar.gz")
+sha256sums=('1b619e326ff574de808732ca9a7447e4cd14e94ae6568f55b6581896cd569dff')
+
+prepare() {
+    mkdir -p build
+}
+
+build() {
+    cd build
+
+    # Flags to enable system libs in VTK building, as in VTK package
+    # NETCDFCPP status?
+    # GL2PS fails.
+    # libharu blocked by https://github.com/libharu/libharu/pull/157
+    # TXAIO HYPERLINK in a future VTK version
+    # LIBPROJ4 apparently not used in this VTK configuration
+    local VTK_USE_SYSTEM_LIB=""
+    for lib in EXPAT FREETYPE JPEG PNG TIFF ZLIB LIBXML2 MPI4PY JSONCPP GLEW HDF5 LZ4 NETCDF
+    do
+        VTK_USE_SYSTEM_LIB+="-DVTK_USE_SYSTEM_${lib}:BOOL=ON "
+    done
+    # Specific system libs for ParaView version
+    for lib in CGNS PUGIXML PROTOBUF PYGMENTS 
+    do
+        VTK_USE_SYSTEM_LIB+="-DVTK_USE_SYSTEM_${lib}:BOOL=ON "
+    done
+
+    cmake ../ParaView-v${pkgver} \
+        -DBUILD_DOCUMENTATION=OFF \
+        -DBUILD_EXAMPLES=ON \
+        -DBUILD_SHARED_LIBS=ON \
+        -DBUILD_TESTING=OFF \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DCMAKE_C_COMPILER=mpicc \
+        -DCMAKE_CXX_COMPILER=mpicxx \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DOSPRAY_INSTALL_DIR=/usr \
+        -DPARAVIEW_ENABLE_FFMPEG=ON \
+        -DPARAVIEW_ENABLE_MATPLOTLIB=ON \
+        -DPARAVIEW_ENABLE_PYTHON=ON \
+        -DPARAVIEW_INSTALL_DEVELOPMENT_FILES=ON \
+        -DPARAVIEW_QT_VERSION=5 \
+        -DPARAVIEW_USE_MPI=ON \
+        -DPARAVIEW_USE_VISITBRIDGE=ON \
+        -DPARAVIEW_USE_OSPRAY=ON \
+        -DVISIT_BUILD_READER_CGNS=ON \
+        -DVTK_PYTHON_FULL_THREADSAFE=ON \
+        -DVTK_PYTHON_VERSION=3 \
+        -DVTK_QT_VERSION=5 \
+        -DVTK_RENDERING_BACKEND=OpenGL2 \
+        -DVTK_SMP_IMPLEMENTATION_TYPE=OpenMP \
+        ${VTK_USE_SYSTEM_LIB} \
+        -GNinja
+
+    ninja ${MAKEFLAGS}
+}
+
+package() {
+    cd build
+
+    DESTDIR="${pkgdir}" ninja install
+
+    # Install license
+    install -Dm644 "${srcdir}"/ParaView-v${pkgver}/License_v1.2.txt "${pkgdir}"/usr/share/licenses/paraview/LICENSE
+
+    # Remove IceT man pages to avoid conflicts
+    rm -- "${pkgdir}"/usr/share/man/man3/icet*.3
+    rmdir "${pkgdir}"/usr/share/man/{man3/,}
+}