[arch-commits] Commit in hedgewars/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Wed Apr 25 07:37:14 UTC 2018
Date: Wednesday, April 25, 2018 @ 07:37:14
Author: felixonmars
Revision: 317812
archrelease: copy trunk to community-staging-x86_64
Added:
hedgewars/repos/community-staging-x86_64/
hedgewars/repos/community-staging-x86_64/PKGBUILD
(from rev 317811, hedgewars/trunk/PKGBUILD)
----------+
PKGBUILD | 59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 59 insertions(+)
Copied: hedgewars/repos/community-staging-x86_64/PKGBUILD (from rev 317811, hedgewars/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2018-04-25 07:37:14 UTC (rev 317812)
@@ -0,0 +1,59 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Tinxy <arch at tinx dot eu>
+
+pkgname=hedgewars
+pkgver=0.9.24
+pkgrel=1
+pkgdesc="Turn-based strategy artillery game similiar to Worms"
+arch=('x86_64')
+url="https://hedgewars.org"
+license=('GPL' 'custom')
+depends=('qt5-base' 'sdl2' 'sdl2_mixer' 'sdl2_image' 'sdl2_net' 'sdl2_ttf' 'lua51' 'ffmpeg' 'glut'
+ 'physfs' 'ghc-libs' 'haskell-entropy' 'haskell-sha' 'haskell-random' 'haskell-regex-tdfa'
+ 'haskell-sandi' 'haskell-hslogger' 'haskell-utf8-string' 'haskell-vector')
+makedepends=('fpc' 'cmake' 'qt5-tools' 'ghc' 'haskell-network' 'haskell-bytestring-show'
+ 'haskell-mtl' 'haskell-stm' 'haskell-zlib' 'haskell-base-prelude' 'imagemagick')
+source=("https://www.hedgewars.org/download/releases/hedgewars-src-$pkgver.tar.bz2"
+ "https://src.fedoraproject.org/rpms/hedgewars/raw/master/f/hedgewars-cmake-ghc8-mask.patch")
+sha512sums=('6f6d5e6b7b460b70ec7e20fd66e96d7ad82d2d8d90aa5e89522268c71b90016343e3edd8a3186314546044639e9623af6d0ee2df38395ea925e5588280db27b1'
+ '957e6cbe868924f0541cfa5a5e7e507caf798c94a1414911a8b8bc466bc4accb8fdd4d52cc298a5b88f83e93fd323cb2344db89df1be173bf6b0daf336b7b3ce')
+
+prepare() {
+ cd hedgewars-src-$pkgver
+ sed -i 's|set(ghc_flags|set(ghc_flags -dynamic|' gameServer/CMakeLists.txt
+ # Fix GHC 8
+ #patch -p1 -i ../hedgewars-cmake-ghc8-mask.patch
+}
+
+build() {
+ cd hedgewars-src-$pkgver
+ cmake \
+ -DCMAKE_BUILD_TYPE="Release" \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DDATA_INSTALL_DIR=/usr/share/hedgewars \
+ -DNOSERVER=0 \
+ .
+ make
+
+ # resize icon
+ for _size in 16 32 48 64 128 256; do
+ convert misc/hedgewars.png -resize ${_size}x${_size} hedgewars_${_size}.png
+ done
+}
+
+package() {
+ cd hedgewars-src-$pkgver
+ make DESTDIR="$pkgdir" install
+ install -D -m644 Fonts_LICENSE.txt "$pkgdir"/usr/share/licenses/${pkgname}/Fonts_LICENSE.txt
+
+ # install icons
+ install -D -m644 misc/hedgewars.png "$pkgdir"/usr/share/icons/hicolor/512x512/apps/hedgewars.png
+ for _size in 16 32 48 64 128 256; do
+ install -D -m644 hedgewars_${_size}.png "$pkgdir"/usr/share/icons/hicolor/${_size}x${_size}/apps/hedgewars.png
+ done
+ rm -rf "$pkgdir"/usr/share/pixmaps
+
+ install -D -m644 share/hedgewars/Data/misc/hedgewars.desktop "$pkgdir"/usr/share/applications/hedgewars.desktop
+}
More information about the arch-commits
mailing list