[arch-commits] Commit in openal/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Wednesday, April 25, 2018 @ 09:58:47
  Author: felixonmars
Revision: 322992

archrelease: copy trunk to staging-x86_64

Added:
  openal/repos/staging-x86_64/
  openal/repos/staging-x86_64/PKGBUILD
    (from rev 322991, openal/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: openal/repos/staging-x86_64/PKGBUILD (from rev 322991, openal/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2018-04-25 09:58:47 UTC (rev 322992)
@@ -0,0 +1,60 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: Jason Chu <jchu at xentac.net>
+
+pkgbase=openal
+pkgname=(openal openal-examples)
+pkgver=1.18.2
+pkgrel=2
+pkgdesc="Cross-platform 3D audio library, software implementation"
+arch=(x86_64)
+url="https://github.com/kcat/openal-soft"
+license=(LGPL)
+depends=(glibc)
+makedepends=(alsa-lib libpulse fluidsynth portaudio jack qt5-base sdl2 sdl_sound ffmpeg
+             git cmake ninja)
+_commit=ce6076091bac3c00cd10803916e8911495580bd0  # tags/openal-soft-1.18.2
+source=("git+https://github.com/kcat/openal-soft#commit=$_commit")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd openal-soft
+  git describe --tags | sed 's/^openal-soft-//;s/-/+/g'
+}
+
+prepare() {
+  mkdir build examples
+  cd openal-soft
+
+  # https://bugs.archlinux.org/task/54908
+  git cherry-pick -n d4f3490a880f779f460332689a396ade69840f50
+}
+
+build() {
+  cd build
+  cmake ../openal-soft -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_LIBDIR=lib
+  ninja
+}
+
+package_openal() {
+  optdepends=('qt5-base: alsoft-config GUI Configurator'
+              'fluidsynth: MIDI rendering')
+
+  DESTDIR="$pkgdir" ninja -C build install
+  install -Dt "$pkgdir/usr/share/doc/openal" -m644 openal-soft/docs/*
+
+### Split openal-examples
+  mv -v "$pkgdir"/usr/bin/al{ffplay,hrtf,latency,loopback,reverb,stream} examples/
+}
+
+package_openal-examples() {
+  pkgdesc+=" (example programs)"
+  depends=("openal=$pkgver-$pkgrel" sdl2 sdl_sound ffmpeg)
+
+  mkdir "$pkgdir/usr"
+  mv -v examples "$pkgdir/usr/bin"
+}