[arch-commits] Commit in haskell-html-conduit/repos (2 files)

[Felix Yan]

    Date: Thursday, August 2, 2018 @ 14:51:02
  Author: felixonmars
Revision: 367320

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-html-conduit/repos/community-staging-x86_64/
  haskell-html-conduit/repos/community-staging-x86_64/PKGBUILD
    (from rev 367319, haskell-html-conduit/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-html-conduit/repos/community-staging-x86_64/PKGBUILD (from rev 367319, haskell-html-conduit/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-08-02 14:51:02 UTC (rev 367320)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=html-conduit
+pkgname=haskell-html-conduit
+pkgver=1.3.1
+pkgrel=24
+pkgdesc="Parse HTML documents using xml-conduit datatypes"
+url="https://github.com/snoyberg/xml"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-resourcet' 'haskell-conduit' 'haskell-xml-conduit'
+         'haskell-attoparsec' 'haskell-conduit-extra' 'haskell-xml-types')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hunit')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('2f6e77f7894459f724ffd1357545eedafcd820160de7bff71f775cc38189ddd78df735c0349ac0ebbf22def2f915e62df795ef32ea1652dc72cd0fa811d76dbf')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}