[arch-commits] Commit in graphicsmagick/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Evangelos Foutras]

    Date: Monday, August 6, 2018 @ 16:35:07
  Author: foutrelis
Revision: 331010

archrelease: copy trunk to staging-x86_64

Added:
  graphicsmagick/repos/staging-x86_64/
  graphicsmagick/repos/staging-x86_64/PKGBUILD
    (from rev 331009, graphicsmagick/trunk/PKGBUILD)

----------+
 PKGBUILD |   66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

Copied: graphicsmagick/repos/staging-x86_64/PKGBUILD (from rev 331009, graphicsmagick/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2018-08-06 16:35:07 UTC (rev 331010)
@@ -0,0 +1,66 @@
+# $Id$
+# Maintainer: Ronald van Haren <ronald.archlinux.org>
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Jaroslav Lichtblau <dragonlord at aur.archlinux.org>
+# Contributor: Anton Leontiev <bunder at t-25.ru>
+
+pkgname=graphicsmagick
+pkgver=1.3.30
+pkgrel=3
+pkgdesc='Image processing system'
+url='http://www.graphicsmagick.org/'
+arch=('x86_64')
+license=('MIT')
+optdepends=('jasper: jp2 module'
+            'libpng: png module'
+            'libwmf: wmf module'
+            'libxml2: msl, svg, url modules'
+            'libtiff: ps2, ps3, tiff modules'
+            'ghostscript: pdf, ps modules')
+makedepends=('perl' 'jasper' 'libpng' 'libwmf' 'libxml2' 'libtiff' 'libwebp')
+depends=('freetype2' 'libxext' 'libsm' 'lcms2' 'libltdl' 'bzip2' 'xz')
+source=("https://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgver}/GraphicsMagick-${pkgver}.tar.xz")
+sha256sums=('d965e5c6559f55eec76c20231c095d4ae682ea0cbdd8453249ae8771405659f1')
+
+options=('!emptydirs' 'libtool')
+
+prepare() {
+	cd "${srcdir}/GraphicsMagick-${pkgver}"
+	sed -e "s:freetype_config='':freetype_config='/usr/bin/pkg-config freetype2':g" -i configure
+}
+
+build() {
+	cd "${srcdir}/GraphicsMagick-${pkgver}"
+	./configure \
+		--prefix=/usr \
+		--enable-shared \
+		--with-modules \
+		--with-perl \
+		--with-gs-font-dir=/usr/share/fonts/Type1 \
+		--with-quantum-depth=16 \
+		--with-threads
+	make
+}
+
+package() {
+	cd "${srcdir}/GraphicsMagick-${pkgver}"
+
+	make DESTDIR="${pkgdir}" install
+
+	# Install MIT license
+	install -Dm644 "Copyright.txt" "${pkgdir}/usr/share/licenses/${pkgname}/Copyright.txt"
+
+	# Install perl bindings
+	# The patching was introduced in order to build perl module without installing package itself and
+	# not to introduce unnecessary path into LD_RUN_PATH
+	cd PerlMagick
+	sed -i -e "s:'LDDLFLAGS'  => \"\(.*\)\":'LDDLFLAGS'  => \"-L${pkgdir}/usr/lib \1\":" Makefile.PL
+	perl Makefile.PL INSTALLDIRS=vendor PREFIX=/usr DESTDIR="${pkgdir}"
+	sed -i -e "s/LDLOADLIBS =/LDLOADLIBS = -lGraphicsMagick/" Makefile
+	make
+	make install
+
+	# Remove perllocal.pod and .packlist
+	rm -r "${pkgdir}"/usr/lib/perl5/*/core_perl
+	rm "${pkgdir}"/usr/lib/perl5/*/vendor_perl/auto/Graphics/Magick/.packlist
+}