[arch-commits] Commit in gnucash/repos (2 files)

[Evangelos Foutras]

    Date: Monday, August 6, 2018 @ 20:14:51
  Author: foutrelis
Revision: 369900

archrelease: copy trunk to community-staging-x86_64

Added:
  gnucash/repos/community-staging-x86_64/
  gnucash/repos/community-staging-x86_64/PKGBUILD
    (from rev 369899, gnucash/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: gnucash/repos/community-staging-x86_64/PKGBUILD (from rev 369899, gnucash/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-08-06 20:14:51 UTC (rev 369900)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Juergen Hoetzel <juergen at archlinux.org>
+# Contributor: Mark Schneider <queueRAM at gmail.com>
+
+pkgname=gnucash
+pkgver=3.2
+pkgrel=4
+pkgdesc='Personal and small-business financial-accounting application'
+arch=(x86_64)
+url='https://gnucash.org/'
+license=(GPL)
+depends=(aqbanking boost-libs guile libdbi webkit2gtk)
+makedepends=(boost cmake gmock libdbi-drivers libmariadbclient postgresql-libs)
+optdepends=('gnucash-docs: documentation'
+            'libdbi-drivers: open and save data into SQL database'
+            'perl-date-manip: stock information lookups'
+            'perl-finance-quote: stock information lookups')
+options=(!emptydirs)
+source=(https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz)
+sha256sums=('beb028b6933f57a6dad89f0c0a54ffe7b5dd42bbd3f532405f4ffd01cc5eaa5c')
+
+build() {
+  cd $pkgname-$pkgver
+
+  # Do not treat warnings as errors
+  CXXFLAGS+=' -Wno-error'
+
+  cmake	-DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_INSTALL_LIBDIR=/usr/lib \
+        -DWITH_PYTHON=ON \
+        -DHAVE_GWEN_GTK3=ON \
+        -DCOMPILE_GSCHEMAS=OFF
+  make
+}
+
+check() {
+  cd $pkgname-$pkgver
+  make -k check || : # 2 tests failed
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+
+  # Delete the gnucash-valgrind executable because the source files
+  # are not included with the package and the executable is hardlinked
+  # to the location that it was built at.
+  rm -f "$pkgdir/usr/bin/gnucash-valgrind"
+}