[arch-commits] Commit in python-pyicu/repos (2 files)

Evangelos Foutras foutrelis at archlinux.org
Mon Aug 6 21:36:43 UTC 2018


    Date: Monday, August 6, 2018 @ 21:36:42
  Author: foutrelis
Revision: 369933

archrelease: copy trunk to community-staging-x86_64

Added:
  python-pyicu/repos/community-staging-x86_64/
  python-pyicu/repos/community-staging-x86_64/PKGBUILD
    (from rev 369932, python-pyicu/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: python-pyicu/repos/community-staging-x86_64/PKGBUILD (from rev 369932, python-pyicu/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-08-06 21:36:42 UTC (rev 369933)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Jonathan Liu <net147 at gmail.com>
+
+pkgbase=python-pyicu
+pkgname=('python-pyicu' 'python2-pyicu')
+pkgver=2.0.3
+pkgrel=4
+pkgdesc="Python binding for ICU"
+arch=('x86_64')
+license=('MIT')
+url="http://pyicu.osafoundation.org/"
+makedepends=('python-setuptools' 'python2-setuptools' 'icu')
+checkdepends=('python-fonttools' 'python2-fonttools' 'python-pytest' 'python2-pytest')
+source=("https://pypi.io/packages/source/P/PyICU/PyICU-$pkgver.tar.gz")
+sha512sums=('a08a34772fc8205660320d7ea1bea52cd9c21ff9edf0aef1059c9439406d4b69ab434b35347dce8928cff8051600d55cb71bcc74eb89f203037be629d83e044e')
+
+prepare() {
+  cp -a PyICU-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir/"PyICU-$pkgver
+  python setup.py build
+
+  cd "$srcdir/"PyICU-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/"PyICU-$pkgver
+  python setup.py test
+
+  cd "$srcdir/"PyICU-$pkgver-py2
+  python2 setup.py test || true # https://github.com/ovalhub/pyicu/issues/61
+}
+
+package_python-pyicu() {
+  depends=('python' 'icu')
+
+  cd PyICU-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-pyicu() {
+  depends=('python2' 'icu')
+
+  cd PyICU-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}



More information about the arch-commits mailing list