[arch-commits] Commit in haskell-microlens-aeson/repos (2 files)

[Felix Yan]

    Date: Tuesday, August 7, 2018 @ 04:51:52
  Author: felixonmars
Revision: 370064

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-microlens-aeson/repos/community-staging-x86_64/
  haskell-microlens-aeson/repos/community-staging-x86_64/PKGBUILD
    (from rev 370063, haskell-microlens-aeson/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-microlens-aeson/repos/community-staging-x86_64/PKGBUILD (from rev 370063, haskell-microlens-aeson/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-08-07 04:51:52 UTC (rev 370064)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=microlens-aeson
+pkgname=haskell-microlens-aeson
+pkgver=2.3.0
+pkgrel=33
+pkgdesc="Law-abiding lenses for Aeson, using microlens"
+url="https://github.com/fosskers/microlens-aeson/"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-hashable' 'haskell-microlens'
+         'haskell-scientific' 'haskell-unordered-containers' 'haskell-vector')
+makedepends=('ghc' 'haskell-tasty' 'haskell-tasty-hunit')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('675c92fdb5f40a5c3c73c93555d55844a5b6b999717545682d80f5fe75b43f8b998af22164b98a034a6e8eea7590bbe1c253b69de6ed2bf411308942108ca804')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/<.*1.4/<2/' $_hkgname.cabal
+    echo -e "import Distribution.Simple\nmain = defaultMain" > Setup.hs
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}