[arch-commits] Commit in gst-plugins-ugly/repos (2 files)

[Maxime Gauduin]

    Date: Tuesday, August 7, 2018 @ 09:49:53
  Author: alucryd
Revision: 331100

archrelease: copy trunk to staging-x86_64

Added:
  gst-plugins-ugly/repos/staging-x86_64/
  gst-plugins-ugly/repos/staging-x86_64/PKGBUILD
    (from rev 331099, gst-plugins-ugly/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: gst-plugins-ugly/repos/staging-x86_64/PKGBUILD (from rev 331099, gst-plugins-ugly/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2018-08-07 09:49:53 UTC (rev 331100)
@@ -0,0 +1,60 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gst-plugins-ugly
+pkgver=1.14.2
+pkgrel=2
+pkgdesc="GStreamer Multimedia Framework Ugly Plugins"
+url="https://gstreamer.freedesktop.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(gst-plugins-base-libs libdvdread libmpeg2 a52dec libsidplay libcdio
+         x264 opencore-amr)
+makedepends=(python gtk-doc autoconf-archive git)
+_commit=df1bcfa0ba57859eb39610ef53f1eb744ca57465  # tags/1.14.2^0
+source=("git+https://anongit.freedesktop.org/git/gstreamer/gst-plugins-ugly#commit=$_commit"
+        "gst-common::git+https://anongit.freedesktop.org/git/gstreamer/common")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.common.url "$srcdir/gst-common"
+  git submodule update
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --libexecdir=/usr/lib \
+    --with-package-name="GStreamer Ugly Plugins (Arch Linux)" \
+    --with-package-origin="https://www.archlinux.org/" \
+    --enable-experimental \
+    --enable-gtk-doc \
+    --disable-static
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}