[arch-commits] Commit in handbrake/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, August 7, 2018 @ 10:12:53
  Author: foutrelis
Revision: 370110

archrelease: copy trunk to community-staging-x86_64

Added:
  handbrake/repos/community-staging-x86_64/
  handbrake/repos/community-staging-x86_64/PKGBUILD
    (from rev 370109, handbrake/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: handbrake/repos/community-staging-x86_64/PKGBUILD (from rev 370109, handbrake/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-08-07 10:12:53 UTC (rev 370110)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Evangelos Foutras <evangelos at foutrelis.com>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: Sebastien Piccand <sebcactus gmail com>
+
+pkgname=('handbrake' 'handbrake-cli')
+pkgver=1.1.1
+pkgrel=2
+arch=('x86_64')
+url="https://handbrake.fr/"
+license=('GPL')
+makedepends=('intltool' 'python2' 'yasm' 'wget' 'cmake' 'bzip2' 'gcc-libs'
+             'zlib' 'libnotify' 'gst-plugins-base' 'gtk3' 'dbus-glib' 'libass'
+             'lame' 'libxml2' 'opus' 'libvorbis' 'libtheora' 'libsamplerate'
+             'x264' 'jansson' 'librsvg' 'libgudev')
+source=(https://download.handbrake.fr/releases/$pkgver/HandBrake-$pkgver-source.tar.bz2
+        https://github.com/HandBrake/HandBrake/releases/download/$pkgver/HandBrake-$pkgver-source.tar.bz2.sig)
+sha256sums=('e3390c5fd901fb06d72e29c62a63d373d5fb5b3467295d114d815ae7b78a9d7a'
+            'SKIP')
+validpgpkeys+=('1629C061B3DDE7EB4AE34B81021DB8B44E4A8645') # HandBrake Team <developers at handbrake.fr>
+
+build() {
+  cd "$srcdir/HandBrake-$pkgver"
+
+  ./configure --prefix=/usr
+  make -C build
+}
+
+package_handbrake() {
+  pkgdesc="Multithreaded video transcoder"
+  depends=('bzip2' 'gcc-libs' 'zlib' 'gst-plugins-base' 'libnotify' 'dbus-glib'
+           'gtk3' 'libass' 'lame' 'libxml2' 'opus' 'libvorbis' 'libtheora'
+           'libsamplerate' 'x264' 'jansson' 'librsvg' 'libgudev'
+           'desktop-file-utils' 'hicolor-icon-theme')
+  optdepends=('gst-plugins-good: for video previews'
+              'gst-libav: for video previews'
+              'libdvdcss: for decoding encrypted DVDs')
+
+  cd "$srcdir/HandBrake-$pkgver/build"
+
+  make DESTDIR="$pkgdir" install
+  rm "$pkgdir/usr/bin/HandBrakeCLI"
+}
+
+package_handbrake-cli() {
+  pkgdesc="Multithreaded video transcoder (CLI)"
+  depends=('bzip2' 'gcc-libs' 'zlib' 'libass' 'lame' 'libxml2' 'opus'
+           'libvorbis' 'libtheora' 'libsamplerate' 'x264' 'jansson')
+  optdepends=('libdvdcss: for decoding encrypted DVDs')
+
+  cd "$srcdir/HandBrake-$pkgver/build"
+  install -D HandBrakeCLI "$pkgdir/usr/bin/HandBrakeCLI"
+}
+
+# vim:set ts=2 sw=2 et: