[arch-commits] Commit in haskell-hspec-wai/repos (2 files)

[Felix Yan]

    Date: Wednesday, August 15, 2018 @ 12:36:28
  Author: felixonmars
Revision: 371752

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hspec-wai/repos/community-staging-x86_64/
  haskell-hspec-wai/repos/community-staging-x86_64/PKGBUILD
    (from rev 371751, haskell-hspec-wai/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-hspec-wai/repos/community-staging-x86_64/PKGBUILD (from rev 371751, haskell-hspec-wai/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-08-15 12:36:28 UTC (rev 371752)
@@ -0,0 +1,46 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=hspec-wai
+pkgname=haskell-hspec-wai
+pkgver=0.9.0
+pkgrel=95
+pkgdesc="Experimental Hspec support for testing WAI applications"
+url="https://github.com/hspec/hspec-wai"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-quickcheck' 'haskell-base-compat' 'haskell-case-insensitive'
+         'haskell-hspec' 'haskell-hspec-core' 'haskell-hspec-expectations' 'haskell-http-types'
+         'haskell-wai' 'haskell-wai-extra')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('47822443b1a141a9ca6f6365a07906f7b11b44c2c999ef80bf6c87e66538a3a9d3e3221f48098414aea3538f7ea957bb3435255a490268b5eaecf3785fec407c')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}