[arch-commits] Commit in cantor/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Friday, August 17, 2018 @ 14:30:09
  Author: arojas
Revision: 331735

archrelease: copy trunk to testing-x86_64

Added:
  cantor/repos/testing-x86_64/
  cantor/repos/testing-x86_64/PKGBUILD
    (from rev 331734, cantor/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: cantor/repos/testing-x86_64/PKGBUILD (from rev 331734, cantor/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2018-08-17 14:30:09 UTC (rev 331735)
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=cantor
+pkgver=18.08.0
+pkgrel=1
+pkgdesc="KDE Frontend to Mathematical Software"
+url="https://kde.org/applications/education/cantor/"
+arch=(x86_64)
+license=(GPL LGPL FDL)
+groups=(kde-applications kdeedu)
+depends=(analitza libspectre kpty ktexteditor knewstuff libqalculate hicolor-icon-theme)
+makedepends=(extra-cmake-modules python python2 kdoctools luajit r julia)
+optdepends=('maxima: Maxima backend'
+            'octave: Octave backend'
+            'r: R backend'
+            'luajit: LUA backend'
+            'python: Python 3 backend'
+	    'python2: Python 2 backend'
+            'sagemath: SageMath backend'
+            'julia: Julia backend')
+source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
+        cantor-julia.patch::"https://cgit.kde.org/cantor.git/patch/?id=90b001d1")
+sha256sums=('be6167ec88504091e9fa9914e0bd1fbb13637fb2b2b228c9274225db6dc85823'
+            'SKIP'
+            '366e1a734a968c4a933e91342308e4d18108c1bc023572848747ca6a2ec656f7')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+  mkdir -p build
+
+  cd $pkgname-$pkgver
+  patch -p1 -i ../cantor-julia.patch # Fix julia backend build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF \
+    -DPYTHON_INCLUDE_DIR=/usr/include/python2.7 \
+    -DPYTHON_LIBRARY=/usr/lib/libpython2.7.so
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}