[arch-commits] Commit in okular/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Friday, August 17, 2018 @ 14:47:05
  Author: arojas
Revision: 331800

archrelease: copy trunk to testing-x86_64

Added:
  okular/repos/testing-x86_64/
  okular/repos/testing-x86_64/PKGBUILD
    (from rev 331799, okular/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: okular/repos/testing-x86_64/PKGBUILD (from rev 331799, okular/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2018-08-17 14:47:05 UTC (rev 331800)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=okular
+pkgver=18.08.0
+pkgrel=1
+pkgdesc='Document Viewer'
+arch=(x86_64)
+url="https://kde.org/applications/graphics/okular/"
+license=(GPL LGPL FDL)
+groups=(kde-applications kdegraphics)
+depends=(djvulibre libspectre libkexiv2 poppler-qt5 qca-qt5 kpty kactivities threadweaver kjs kparts purpose)
+makedepends=(extra-cmake-modules ebook-tools kdegraphics-mobipocket kdoctools khtml chmlib discount)
+optdepends=('ebook-tools: mobi and epub support' 'discount: markdown support'
+            'kdegraphics-mobipocket: mobi support' 'kirigami2: mobile UI' 'libzip: CHM support'
+            'khtml: CHM support' 'chmlib: CHM support' 'calligra: ODT and ODP support'
+            'unrar: Comic Book Archive support')
+conflicts=(kdegraphics-okular)
+replaces=(kdegraphics-okular)
+source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('f6a27b9b2707358dfed713458ed52cb1ac7dbc48ce3c06bfe04dd0b036809c87'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}