[arch-commits] Commit in telepathy-kde-accounts-kcm/repos (2 files)

[Antonio Rojas]

    Date: Friday, August 17, 2018 @ 14:52:05
  Author: arojas
Revision: 331820

archrelease: copy trunk to testing-x86_64

Added:
  telepathy-kde-accounts-kcm/repos/testing-x86_64/
  telepathy-kde-accounts-kcm/repos/testing-x86_64/PKGBUILD
    (from rev 331819, telepathy-kde-accounts-kcm/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: telepathy-kde-accounts-kcm/repos/testing-x86_64/PKGBUILD (from rev 331819, telepathy-kde-accounts-kcm/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2018-08-17 14:52:05 UTC (rev 331820)
@@ -0,0 +1,41 @@
+# $Id$
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Laurent Carlier <lordheavym at gmail.com>
+
+pkgname=telepathy-kde-accounts-kcm
+_pkgname=ktp-accounts-kcm
+pkgver=18.08.0
+pkgrel=1
+pkgdesc='KCM Module for configuring Telepathy Instant Messaging Accounts'
+arch=(x86_64)
+url='https://community.kde.org/Real-Time_Communication_and_Collaboration'
+license=(GPL)
+groups=(kde-applications kdenetwork telepathy-kde)
+depends=(telepathy-qt kaccounts-providers)
+makedepends=(extra-cmake-modules intltool)
+optdepends=('telepathy-gabble: XMPP/Jabber accounts support' 'telepathy-haze: account types supported by Pidgin/libpurple'
+            'telepathy-morse: Telegram accounts support' 'telepathy-salut: link-local XMPP account support')
+source=("https://download.kde.org/stable/applications/$pkgver/src/$_pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('a4c89069b3e83230b7f02532a93f31d7f2f78d4db65a5bf5a3e29523f36d679a'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$_pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}