[arch-commits] Commit in gthumb/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Saturday, August 18, 2018 @ 13:50:50
  Author: arojas
Revision: 332270

archrelease: copy trunk to staging-x86_64

Added:
  gthumb/repos/staging-x86_64/
  gthumb/repos/staging-x86_64/PKGBUILD
    (from rev 332269, gthumb/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: gthumb/repos/staging-x86_64/PKGBUILD (from rev 332269, gthumb/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2018-08-18 13:50:50 UTC (rev 332270)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Tobias Kieslich <tobias at justdreams.de>
+
+pkgname=gthumb
+pkgver=3.6.1
+pkgrel=2
+pkgdesc="Image browser and viewer for the GNOME Desktop"
+url="https://wiki.gnome.org/Apps/gthumb"
+arch=(x86_64)
+license=(GPL)
+depends=(dconf librsvg clutter-gtk gst-plugins-base-libs gsettings-desktop-schemas libwebp
+         libsecret libsoup webkit2gtk json-glib gtk3-print-backends)
+makedepends=(intltool libchamplain exiv2 itstool brasero libraw liboauth docbook-xsl
+             yelp-tools flex gnome-common git)
+options=(debug !strip)          
+optdepends=('libraw: read RAW files'
+            'exiv2: metadata support'
+            'libchamplain: map viewer'
+            'brasero: burn discs'
+            'liboauth: web albums')
+_commit=748001c0addbe516843ed0e64dd42740eaa7aa76  # tags/3.6.1^0
+source=("git+https://git.gnome.org/browse/gthumb#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var --disable-static \
+      --enable-libchamplain
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}