[arch-commits] Commit in digikam (kde-unstable kde-unstable/PKGBUILD)

[Antonio Rojas]

    Date: Sunday, August 19, 2018 @ 19:50:12
  Author: arojas
Revision: 332662

Update to 6.0.0-beta1

Added:
  digikam/kde-unstable/
  digikam/kde-unstable/PKGBUILD

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Added: kde-unstable/PKGBUILD
===================================================================
--- kde-unstable/PKGBUILD	                        (rev 0)
+++ kde-unstable/PKGBUILD	2018-08-19 19:50:12 UTC (rev 332662)
@@ -0,0 +1,46 @@
+# $Id: PKGBUILD 320127 2018-03-24 09:48:28Z arojas $
+# Maintainer: Ronald van Haren <ronald at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Tobias Powalowski <tpowa at archlinux.org>
+
+pkgname=digikam
+_pkgver=6.0.0-beta1
+pkgver=${_pkgver//-/_} # for beta versions
+pkgrel=1
+pkgdesc="An advanced digital photo management application"
+arch=(x86_64)
+license=(GPL)
+url="http://www.digikam.org/"
+depends=(liblqr lensfun opencv akonadi-contacts knotifyconfig libksane kfilemetadata qtav marble-common threadweaver kcalcore
+         qt5-webengine libkvkontakte libmediawiki)
+makedepends=(extra-cmake-modules libkipi libksane liblqr opencv doxygen lensfun eigen boost kdoctools)
+optdepends=('hugin: panorama tool' 'qt5-imageformats: support for additional image formats (WEBP, TIFF)')
+source=("http://download.kde.org/stable/${pkgname}/${pkgname}-${_pkgver}.tar.xz")
+sha256sums=('43bde5b12b261e8aacb95948103c499389153af7d9e5527bd278781a4f3ea020')
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+
+  cmake ../$pkgname-${_pkgver} \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF \
+    -DENABLE_KFILEMETADATASUPPORT=ON \
+    -DENABLE_MEDIAPLAYER=ON \
+    -DENABLE_AKONADICONTACTSUPPORT=ON \
+    -DENABLE_MYSQLSUPPORT=ON \
+    -DENABLE_APPSTYLES=ON \
+    -DENABLE_QWEBENGINE=ON \
+    -DOpenGL_GL_PREFERENCE=GLVND
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}