[arch-commits] Commit in oxygen/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Antonio Rojas]

    Date: Thursday, August 23, 2018 @ 22:06:00
  Author: arojas
Revision: 332890

archrelease: copy trunk to extra-x86_64

Added:
  oxygen/repos/extra-x86_64/PKGBUILD
    (from rev 332889, oxygen/trunk/PKGBUILD)
Deleted:
  oxygen/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  106 ++++++++++++++++++++++++-------------------------------------
 1 file changed, 42 insertions(+), 64 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2018-08-23 22:05:40 UTC (rev 332889)
+++ PKGBUILD	2018-08-23 22:06:00 UTC (rev 332890)
@@ -1,64 +0,0 @@
-# $Id$
-# Maintainer: Felix Yan <felixonmars at archlinux.org>
-# Maintainer: Antonio Rojas <arojas at archlinux.org>
-# Contributor: Andrea Scarpino <andrea at archlinux.org>
-
-pkgbase=oxygen
-pkgname=(oxygen oxygen-kde4)
-pkgver=5.13.4
-pkgrel=1
-arch=(x86_64)
-url='https://www.kde.org/workspaces/plasmadesktop/'
-license=(LGPL)
-makedepends=(frameworkintegration kcmutils kdecoration extra-cmake-modules kdoctools kdelibs automoc4 kwayland)
-source=("https://download.kde.org/stable/plasma/$pkgver/$pkgname-$pkgver.tar.xz"{,.sig})
-sha256sums=('426e621984e64f77ea477a1397550d3fcd2ef10efb3dc564a16d39b249fa6500'
-            'SKIP')
-validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell
-              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah at kde.org>
-              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson
-              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart at gmail.com>
-
-prepare() {
-  mkdir -p build{,-kde4}
-}
-
-build() {
-  cd build
-  cmake ../$pkgname-$pkgver \
-    -DCMAKE_INSTALL_PREFIX=/usr \
-    -DCMAKE_INSTALL_LIBDIR=lib \
-    -DBUILD_TESTING=OFF
-  make
-  cd ..
-
-  cd build-kde4
-  cmake ../$pkgname-$pkgver \
-    -DCMAKE_INSTALL_PREFIX=/usr \
-    -DBUILD_TESTING=OFF \
-    -DUSE_KDE4=ON
-  make
-}
-
-package_oxygen() {
-  pkgdesc='KDE Oxygen style'
-  depends=(frameworkintegration kdecoration kcmutils kwayland hicolor-icon-theme)
-  conflicts=(oxygen-cursors)
-  replaces=(oxygen-cursors)
-  groups=(plasma)
-
-  cd build
-  make DESTDIR="$pkgdir" install
-}
-
-package_oxygen-kde4() {
-  pkgdesc='KDE Oxygen style for KDE4 applications'
-  depends=(kdelibs)
-
-  cd build-kde4
-  make DESTDIR="$pkgdir" install
-
-  # needed so that pure Qt4 apps are correctly themed
-  install -d -m755 "$pkgdir"/usr/lib/qt4/plugins/styles
-  ln -s /usr/lib/kde4/plugins/styles/oxygen.so "$pkgdir"/usr/lib/qt4/plugins/styles
-}

Copied: oxygen/repos/extra-x86_64/PKGBUILD (from rev 332889, oxygen/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2018-08-23 22:06:00 UTC (rev 332890)
@@ -0,0 +1,42 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=oxygen
+pkgdesc='KDE Oxygen style'
+pkgver=5.13.4
+pkgrel=2
+arch=(x86_64)
+url='https://www.kde.org/workspaces/plasmadesktop/'
+license=(LGPL)
+depends=(frameworkintegration kdecoration kwayland hicolor-icon-theme)
+makedepends=(extra-cmake-modules kdoctools kcmutils)
+optdepends=('kcmutils: for oxygen-settings5')
+groups=(plasma)
+source=("https://download.kde.org/stable/plasma/$pkgver/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('426e621984e64f77ea477a1397550d3fcd2ef10efb3dc564a16d39b249fa6500'
+            'SKIP')
+validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell
+              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah at kde.org>
+              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson
+              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart at gmail.com>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgbase-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+  cd ..
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}