[arch-commits] Commit in haskell-wai-extra/repos (2 files)

[Felix Yan]

    Date: Sunday, August 26, 2018 @ 09:44:57
  Author: felixonmars
Revision: 374055

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-wai-extra/repos/community-staging-x86_64/
  haskell-wai-extra/repos/community-staging-x86_64/PKGBUILD
    (from rev 374054, haskell-wai-extra/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-wai-extra/repos/community-staging-x86_64/PKGBUILD (from rev 374054, haskell-wai-extra/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-08-26 09:44:57 UTC (rev 374055)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=wai-extra
+pkgname=haskell-wai-extra
+pkgver=3.0.24.2
+pkgrel=2
+pkgdesc="Provides some basic WAI handlers and middleware."
+url="https://github.com/yesodweb/wai"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-terminal' 'haskell-base64-bytestring'
+         'haskell-case-insensitive' 'haskell-cookie' 'haskell-data-default-class'
+         'haskell-fast-logger' 'haskell-http-types' 'haskell-iproute' 'haskell-lifted-base'
+         'haskell-network' 'haskell-old-locale' 'haskell-resourcet' 'haskell-streaming-commons'
+         'haskell-stringsearch' 'haskell-unix-compat' 'haskell-vault' 'haskell-void' 'haskell-wai'
+         'haskell-wai-logger' 'haskell-word8' 'haskell-zlib')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hunit')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('23fbc80823f375a3ee116056709c5b8ab87f237ddf826d5a2acf0d474817959fde76ce27d9fe9bcf80eb863d5196d799cc4bd8bccddd45ab0ea1b057fe19a6e4')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-build-example
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}