[arch-commits] Commit in json-c/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Thursday, August 30, 2018 @ 19:24:12
  Author: heftig
Revision: 333132

archrelease: copy trunk to testing-x86_64

Added:
  json-c/repos/testing-x86_64/
  json-c/repos/testing-x86_64/PKGBUILD
    (from rev 333131, json-c/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: json-c/repos/testing-x86_64/PKGBUILD (from rev 333131, json-c/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2018-08-30 19:24:12 UTC (rev 333132)
@@ -0,0 +1,50 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Geoffroy Carrier <geoffroy.carrier at koon.fr>
+# Contributor: congyiwu <congyiwu AT gmail DOT com>
+
+pkgname=json-c
+pkgver=0.13.1
+pkgrel=2
+pkgdesc="A JSON implementation in C"
+url="https://github.com/json-c/json-c/wiki"
+license=(MIT)
+arch=(x86_64)
+depends=(glibc)
+makedepends=(git)
+_commit=985c46fec39d1d3043f98e8d8cdb9d040131b3bb  # tags/json-c-0.13.1-20180305^0
+source=("git+https://github.com/json-c/json-c#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd json-c
+  local tag="$(git describe --tags --abbrev=0)"
+  local ver="$(git describe --tags)"
+  echo "${tag%-*}${ver#$tag}" | sed 's/^json-c-//;s/-/+/g'
+}
+
+prepare() {
+  cd json-c
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd json-c
+  ./configure \
+    --prefix=/usr \
+    --disable-static \
+    --enable-threading
+  make
+}
+
+check() {
+  cd json-c
+  make check
+}
+
+package() {
+  cd json-c
+  make DESTDIR="$pkgdir" install
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
+}
+
+# vim:set sw=2 et: