[arch-commits] Commit in fmt (repos repos/extra-x86_64 repos/extra-x86_64/PKGBUILD)

Maxime Gauduin alucryd at archlinux.org
Mon Dec 3 10:06:40 UTC 2018


    Date: Monday, December 3, 2018 @ 10:06:39
  Author: alucryd
Revision: 340966

archrelease: copy trunk to extra-x86_64

Added:
  fmt/repos/
  fmt/repos/extra-x86_64/
  fmt/repos/extra-x86_64/PKGBUILD
    (from rev 340965, fmt/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: fmt/repos/extra-x86_64/PKGBUILD (from rev 340965, fmt/trunk/PKGBUILD)
===================================================================
--- repos/extra-x86_64/PKGBUILD	                        (rev 0)
+++ repos/extra-x86_64/PKGBUILD	2018-12-03 10:06:39 UTC (rev 340966)
@@ -0,0 +1,47 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Mihai Bişog <mihai.bisog at gmail.com>
+pkgname=fmt
+pkgver=5.2.1
+pkgrel=1
+pkgdesc='Open-source formatting library for C++'
+arch=(x86_64)
+url='http://fmtlib.net'
+license=(BSD)
+makedepends=(
+  cmake
+  git
+  ninja
+)
+
+source=(git+https://github.com/fmtlib/fmt.git#tag=${pkgver})
+sha256sums=(SKIP)
+
+prepare() {
+  if [[ -d build ]]; then
+    rm -rf build
+  fi
+  mkdir build
+}
+
+build() {
+  cd build
+
+  cmake ../fmt \
+    -G Ninja \
+    -DCMAKE_BUILD_TYPE='Release' \
+    -DCMAKE_INSTALL_PREFIX='/usr' \
+    -DCMAKE_INSTALL_LIBDIR='/usr/lib' \
+    -DBUILD_SHARED_LIBS='1'
+  cmake --build .
+}
+
+check() {
+  cmake --build build --target test
+}
+
+package() {
+  DESTDIR="${pkgdir}" cmake --build build --target install
+  install -Dm 644 fmt/LICENSE.rst -t "${pkgdir}"/usr/share/licenses/fmt
+}
+
+# vim: ts=2 sw=2 et:


More information about the arch-commits mailing list