[arch-commits] Commit in pandoc-citeproc/repos (2 files)

Felix Yan felixonmars at archlinux.org
Thu Dec 6 17:57:23 UTC 2018


    Date: Thursday, December 6, 2018 @ 17:57:22
  Author: felixonmars
Revision: 411897

archrelease: copy trunk to community-staging-x86_64

Added:
  pandoc-citeproc/repos/community-staging-x86_64/
  pandoc-citeproc/repos/community-staging-x86_64/PKGBUILD
    (from rev 411896, pandoc-citeproc/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: pandoc-citeproc/repos/community-staging-x86_64/PKGBUILD (from rev 411896, pandoc-citeproc/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-12-06 17:57:22 UTC (rev 411897)
@@ -0,0 +1,56 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=pandoc-citeproc
+pkgver=0.15.0.1
+pkgrel=4
+pkgdesc="Supports using pandoc with citeproc"
+url="https://hackage.haskell.org/package/$pkgname"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-aeson-pretty' 'haskell-attoparsec' 'haskell-base-compat'
+         'haskell-data-default' 'haskell-hs-bibutils' 'haskell-old-locale' 'pandoc'
+         'haskell-pandoc-types' 'haskell-rfc5051' 'haskell-setenv' 'haskell-split'
+         'haskell-syb' 'haskell-tagsoup' 'haskell-temporary' 'haskell-text-icu'
+         'haskell-unordered-containers' 'haskell-vector' 'haskell-xml-conduit' 'haskell-yaml')
+conflicts=('haskell-pandoc-citeproc')
+replaces=('haskell-pandoc-citeproc')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/$pkgname/${pkgver}/$pkgname-${pkgver}.tar.gz")
+sha512sums=('7a7bc7431c6afcec7a1b825f972d5bcda975e23f770b92c13bdaeb42bb6cc0f267ed71b58047ca263f0537e1b3ff3a095e80747f714a1d256234a6e44ec7254f')
+
+prepare() {
+    cd "${srcdir}/$pkgname-${pkgver}"
+    # TODO: find a better solution
+    sed -i "s|(\"HOME\",\".\")|(\"HOME\",\".\"),(\"LD_LIBRARY_PATH\",\"$PWD/dist/build\"),(\"pandoc_citeproc_datadir\",\"$PWD\")|" tests/test-pandoc-citeproc.hs
+}
+
+build() {
+    cd "${srcdir}/$pkgname-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/$pkgname" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-debug -f-test_citeproc -funicode_collation -f-embed_data_files -fbibutils -f-static
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    # https://github.com/jgm/pandoc-citeproc/issues/342
+    runhaskell Setup test || warning "Tests failed"
+}
+
+package() {
+    cd "${srcdir}/$pkgname-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/$pkgname.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/$pkgname.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/$pkgname/LICENSE"
+}


More information about the arch-commits mailing list