[arch-commits] Commit in haskell-aws/repos (2 files)

Felix Yan felixonmars at archlinux.org
Tue Dec 11 16:50:41 UTC 2018


    Date: Tuesday, December 11, 2018 @ 16:50:38
  Author: felixonmars
Revision: 415418

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-aws/repos/community-staging-x86_64/
  haskell-aws/repos/community-staging-x86_64/PKGBUILD
    (from rev 415417, haskell-aws/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: haskell-aws/repos/community-staging-x86_64/PKGBUILD (from rev 415417, haskell-aws/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-12-11 16:50:38 UTC (rev 415418)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=aws
+pkgname=haskell-aws
+pkgver=0.20
+pkgrel=123
+pkgdesc="Amazon Web Services (AWS) for Haskell"
+url="https://github.com/aristidb/aws"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-base16-bytestring'
+         'haskell-base64-bytestring' 'haskell-blaze-builder' 'haskell-byteable'
+         'haskell-case-insensitive' 'haskell-cereal' 'haskell-conduit' 'haskell-conduit-extra'
+         'haskell-cryptonite' 'haskell-data-default' 'haskell-exceptions' 'haskell-http-conduit'
+         'haskell-http-types' 'haskell-lifted-base' 'haskell-memory' 'haskell-monad-control'
+         'haskell-network' 'haskell-old-locale' 'haskell-resourcet' 'haskell-safe'
+         'haskell-scientific' 'haskell-tagged' 'haskell-unordered-containers'
+         'haskell-utf8-string' 'haskell-vector' 'haskell-xml-conduit')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-errors' 'haskell-http-client'
+             'haskell-http-client-tls' 'haskell-quickcheck-instances' 'haskell-tasty'
+             'haskell-tasty-hunit' 'haskell-tasty-quickcheck' 'haskell-transformers-base')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('b6c9b78c1918fc01057ac3c9f57c98d0d796a228b2efce7f4b8763e6ba86fdad0e29637359a1f2f830adb19cdaade20c4eb08bbe9259bbc79da718771ac5f821')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-examples
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test || warning "Requires AWS credentials to test"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


More information about the arch-commits mailing list