[arch-commits] Commit in kmail/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Antonio Rojas
arojas at archlinux.org
Thu Dec 13 12:01:48 UTC 2018
Date: Thursday, December 13, 2018 @ 12:01:47
Author: arojas
Revision: 341816
archrelease: copy trunk to testing-x86_64
Added:
kmail/repos/testing-x86_64/
kmail/repos/testing-x86_64/PKGBUILD
(from rev 341815, kmail/trunk/PKGBUILD)
----------+
PKGBUILD | 40 ++++++++++++++++++++++++++++++++++++++++
1 file changed, 40 insertions(+)
Copied: kmail/repos/testing-x86_64/PKGBUILD (from rev 341815, kmail/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2018-12-13 12:01:47 UTC (rev 341816)
@@ -0,0 +1,40 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=kmail
+pkgver=18.12.0
+pkgrel=1
+pkgdesc="KDE mail client"
+arch=(x86_64)
+url="https://kontact.kde.org"
+license=(GPL2)
+depends=(kdepim-runtime kmail-account-wizard akonadi-import-wizard mbox-importer
+ pim-data-exporter pim-sieve-editor kontactinterface ktnef)
+makedepends=(extra-cmake-modules kdoctools boost)
+optdepends=('kleopatra: mail encryption support' 'kdepim-addons: additional plugins')
+conflicts=('ktnef<18')
+replaces=('ktnef<18')
+groups=(kde-applications kdepim)
+source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('5d1018d901faa4c72910f1214fb3b3dbe1335f6a4e96b696c75b3179d9a17f47'
+ 'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7 # Albert Astals Cid <aacid at kde.org>
+ F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+ mkdir -p build
+}
+
+build() {
+ cd build
+ cmake ../$pkgname-$pkgver \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DBUILD_TESTING=OFF
+ make
+}
+
+package() {
+ cd build
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list