[arch-commits] Commit in nghttp2/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Anatol Pomozov]

    Date: Saturday, December 15, 2018 @ 07:20:24
  Author: anatolik
Revision: 342372

archrelease: copy trunk to testing-x86_64

Added:
  nghttp2/repos/testing-x86_64/
  nghttp2/repos/testing-x86_64/PKGBUILD
    (from rev 342371, nghttp2/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: nghttp2/repos/testing-x86_64/PKGBUILD (from rev 342371, nghttp2/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2018-12-15 07:20:24 UTC (rev 342372)
@@ -0,0 +1,46 @@
+# Maintainer: Anatol Pomozov
+# Contributor: Zhuoyun Wei <wzyboy at wzyboy.org>
+
+pkgname=nghttp2
+pkgver=1.35.1
+pkgrel=1
+pkgdesc='Framing layer of HTTP/2 is implemented as a reusable C library'
+arch=(x86_64)
+url='https://nghttp2.org/'
+license=(MIT)
+depends=(openssl libev zlib libxml2 jansson jemalloc c-ares libnghttp2 libsystemd)
+options=(!emptydirs)
+source=(https://github.com/nghttp2/nghttp2/releases/download/v$pkgver/nghttp2-$pkgver.tar.xz)
+backup=(
+  etc/nghttpx/nghttpx.conf
+  etc/logrotate.d/nghttpx
+)
+sha512sums=('fcd3f79f913afbeee1c75003bb39df918e6122bbf728b3ad4192d5849d8fb96705e04f5505465d63f25a565b2f1da6abd8fabdebb6e3347500f7abd31980861d')
+
+build() {
+  cd nghttp2-$pkgver
+
+  autoreconf -i
+  ./configure \
+    --prefix=/usr \
+    --disable-examples \
+    --disable-python-bindings
+  make
+}
+
+check() {
+  cd nghttp2-$pkgver
+  make check
+}
+
+package() {
+  cd nghttp2-$pkgver
+
+  make DESTDIR="$pkgdir" install
+  make -C lib DESTDIR="$pkgdir" uninstall
+
+  install -Dm644 contrib/nghttpx.service "$pkgdir/usr/lib/systemd/system/nghttpx.service"
+  install -Dm644 contrib/nghttpx-logrotate "$pkgdir/etc/logrotate.d/nghttpx"
+  install -Dm644 nghttpx.conf.sample "$pkgdir/etc/nghttpx/nghttpx.conf"
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/nghttp2/COPYING"
+}