[arch-commits] Commit in (18 files)
Balló György
bgyorgy at archlinux.org
Sat Dec 15 10:17:36 UTC 2018
Date: Saturday, December 15, 2018 @ 10:17:35
Author: bgyorgy
Revision: 416354
Move fragments, gnome-passwordsafe and gnome-podcasts from AUR
And move their dependencies: libhandy, python-argon2_cffi, python-pykeepass.
Added:
fragments/
fragments/trunk/
fragments/trunk/PKGBUILD
gnome-passwordsafe/
gnome-passwordsafe/trunk/
gnome-passwordsafe/trunk/PKGBUILD
gnome-podcasts/
gnome-podcasts/trunk/
gnome-podcasts/trunk/PKGBUILD
libhandy/
libhandy/trunk/
libhandy/trunk/PKGBUILD
python-argon2_cffi/
python-argon2_cffi/trunk/
python-argon2_cffi/trunk/PKGBUILD
python-pykeepass/
python-pykeepass/trunk/
python-pykeepass/trunk/PKGBUILD
-----------------------------------+
fragments/trunk/PKGBUILD | 63 ++++++++++++++++++++++++++++++++++++
gnome-passwordsafe/trunk/PKGBUILD | 32 ++++++++++++++++++
gnome-podcasts/trunk/PKGBUILD | 37 +++++++++++++++++++++
libhandy/trunk/PKGBUILD | 29 ++++++++++++++++
python-argon2_cffi/trunk/PKGBUILD | 59 +++++++++++++++++++++++++++++++++
python-pykeepass/trunk/PKGBUILD | 31 +++++++++++++++++
6 files changed, 251 insertions(+)
Added: fragments/trunk/PKGBUILD
===================================================================
--- fragments/trunk/PKGBUILD (rev 0)
+++ fragments/trunk/PKGBUILD 2018-12-15 10:17:35 UTC (rev 416354)
@@ -0,0 +1,63 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=fragments
+pkgver=1.2
+pkgrel=1
+pkgdesc="BitTorrent client for GNOME"
+arch=(x86_64)
+url="https://github.com/haecker-felix/Fragments"
+license=(GPL3)
+depends=(curl libevent libhandy libnatpmp miniupnpc)
+makedepends=(cmake git meson vala)
+_commit=2e9b61e6c25cdfbcbe23032fa0242e76fb1d5ffd # tags/1.2
+source=("git+https://github.com/haecker-felix/Fragments#commit=$_commit"
+ "git+https://github.com/transmission/transmission"
+ "git+https://github.com/transmission/dht"
+ "git+https://github.com/transmission/libb64"
+ "git+https://github.com/transmission/libevent"
+ "git+https://github.com/transmission/libnatpmp"
+ "git+https://github.com/transmission/libutp"
+ "git+https://github.com/transmission/miniupnpc")
+sha256sums=('SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd Fragments
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd Fragments
+ git submodule init
+ git config --local submodule.submodules/transmission.url "$srcdir/transmission"
+ git submodule update
+
+ cd submodules/transmission
+ git submodule init
+ git config --local submodule.third-party/dht.url "$srcdir/dht"
+ git config --local submodule.third-party/libb64.url "$srcdir/libb64"
+ git config --local submodule.third-party/libevent.url "$srcdir/libevent"
+ git config --local submodule.third-party/libnatpmp.url "$srcdir/libnatpmp"
+ git config --local submodule.third-party/libutp.url "$srcdir/libutp"
+ git config --local submodule.third-party/miniupnpc.url "$srcdir/miniupnpc"
+ git submodule update
+}
+
+build() {
+ arch-meson Fragments build
+ ninja -C build
+}
+
+check() {
+ meson test -C build
+}
+
+package() {
+ DESTDIR="$pkgdir" meson install -C build
+}
Property changes on: fragments/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: gnome-passwordsafe/trunk/PKGBUILD
===================================================================
--- gnome-passwordsafe/trunk/PKGBUILD (rev 0)
+++ gnome-passwordsafe/trunk/PKGBUILD 2018-12-15 10:17:35 UTC (rev 416354)
@@ -0,0 +1,32 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=gnome-passwordsafe
+pkgver=3.30.2
+pkgrel=1
+pkgdesc="Password manager for GNOME which makes use of the KeePass v.4 format"
+arch=(any)
+url="https://gitlab.gnome.org/World/PasswordSafe"
+license=(GPL3)
+depends=(libhandy python-pykeepass)
+makedepends=(git gobject-introspection meson)
+_commit=a480c5b1b7746e45f26ec682f571d10195ea3eb7 # tags/3.30.2
+source=("git+https://gitlab.gnome.org/World/PasswordSafe.git/#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd PasswordSafe
+ git describe --tags | sed 's/-/+/g'
+}
+
+build() {
+ arch-meson PasswordSafe build
+ ninja -C build
+}
+
+check() {
+ meson test -C build
+}
+
+package() {
+ DESTDIR="$pkgdir" meson install -C build
+}
Property changes on: gnome-passwordsafe/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: gnome-podcasts/trunk/PKGBUILD
===================================================================
--- gnome-podcasts/trunk/PKGBUILD (rev 0)
+++ gnome-podcasts/trunk/PKGBUILD 2018-12-15 10:17:35 UTC (rev 416354)
@@ -0,0 +1,37 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=gnome-podcasts
+pkgver=0.4.6
+pkgrel=1
+pkgdesc="Podcast application for GNOME"
+arch=(x86_64)
+url="https://gitlab.gnome.org/World/podcasts"
+license=(GPL3)
+depends=(gst-plugins-bad gst-plugins-base gst-plugins-good libhandy)
+makedepends=(git meson rust)
+optdepends=('gst-plugins-ugly: Extra media codecs'
+ 'gst-libav: Extra media codecs')
+_commit=885b796f855b659c2d3dda1b7f7e22e7e726ff43 # tags/0.4.6
+source=("git+https://gitlab.gnome.org/World/podcasts.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd podcasts
+ git describe --tags | sed 's/-/+/g'
+}
+
+build() {
+ cd podcasts
+ arch-meson . build
+ ninja -C build
+}
+
+check() {
+ cd podcasts
+ meson test -C build
+}
+
+package() {
+ cd podcasts
+ DESTDIR="$pkgdir" meson install -C build
+}
Property changes on: gnome-podcasts/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: libhandy/trunk/PKGBUILD
===================================================================
--- libhandy/trunk/PKGBUILD (rev 0)
+++ libhandy/trunk/PKGBUILD 2018-12-15 10:17:35 UTC (rev 416354)
@@ -0,0 +1,29 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=libhandy
+pkgver=0.0.5
+pkgrel=1
+pkgdesc="Library full of GTK+ widgets for mobile phones"
+arch=(x86_64)
+url="https://source.puri.sm/Librem5/libhandy"
+license=(LGPL2.1)
+depends=(gtk3)
+makedepends=(git glade gobject-introspection meson vala)
+_commit=9c99704e4cc02d8aff8c03ebd583197677f67e52 # tags/v0.0.5^0
+source=("git+https://source.puri.sm/Librem5/libhandy.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+build() {
+ arch-meson $pkgname build -Dgtk_doc=true
+ ninja -C build
+}
+
+package() {
+ DESTDIR="$pkgdir" meson install -C build
+ rm -r "$pkgdir"/usr/{bin,subdir}
+}
Property changes on: libhandy/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: python-argon2_cffi/trunk/PKGBUILD
===================================================================
--- python-argon2_cffi/trunk/PKGBUILD (rev 0)
+++ python-argon2_cffi/trunk/PKGBUILD 2018-12-15 10:17:35 UTC (rev 416354)
@@ -0,0 +1,59 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+_pkgbase=argon2_cffi
+pkgbase=python-argon2_cffi
+pkgname=('python2-argon2_cffi' 'python-argon2_cffi')
+pkgver=18.3.0
+pkgrel=1
+pkgdesc="CFFI-based Argon2 Bindings for Python"
+arch=('x86_64')
+url="https://github.com/hynek/argon2_cffi"
+license=('MIT')
+depends=(argon2 python-cffi python-six python2-cffi python2-enum34 python2-six)
+makedepends=(git python-setuptools python2-setuptools)
+_commit=f0b0d8fc4baa820fc0d5612f9384f6c95a0ed5c1 # tags/18.3.0^0
+source=("git+https://github.com/hynek/argon2_cffi#commit=$_commit"
+ "https://github.com/p-h-c/phc-winner-argon2")
+sha256sums=('SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd $_pkgbase
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $_pkgbase
+ git submodule init
+ git config --local submodule.extras/libargon2.url "$srcdir/phc-winner-argon2"
+ git submodule update
+ cd ..
+
+ cp -a $_pkgbase{,-py2}
+}
+
+build() {
+ # Building Python2
+ cd $_pkgbase-py2
+ python2 setup.py build
+
+ # Building Python3
+ cd ../$_pkgbase
+ python3 setup.py build
+}
+
+package_python2-argon2_cffi() {
+ depends=(argon2 python2-cffi python2-enum34 python2-six)
+
+ cd $_pkgbase-py2
+ python2 setup.py install --root="$pkgdir" --optimize=1
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python-argon2_cffi() {
+ depends=(argon2 python-cffi python-six)
+
+ cd $_pkgbase
+ python3 setup.py install --root="$pkgdir" --optimize=1
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
Property changes on: python-argon2_cffi/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: python-pykeepass/trunk/PKGBUILD
===================================================================
--- python-pykeepass/trunk/PKGBUILD (rev 0)
+++ python-pykeepass/trunk/PKGBUILD 2018-12-15 10:17:35 UTC (rev 416354)
@@ -0,0 +1,31 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+_pkgname=pykeepass
+pkgname=python-pykeepass
+pkgver=3.0.2
+pkgrel=1
+pkgdesc="Python library to interact with keepass databases"
+arch=('any')
+url="https://github.com/pschmitt/pykeepass"
+license=('GPL3')
+depends=(python-argon2_cffi python-construct python-dateutil python-lxml python-pycryptodome)
+makedepends=(git python-setuptools)
+_commit=76b9e06d1de6f143114c84c33dee849c32e09525 # tags/3.0.2^0
+source=("git+https://github.com/pschmitt/pykeepass#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $_pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+build() {
+ cd $_pkgname
+ python3 setup.py build
+}
+
+package() {
+ cd $_pkgname
+ python3 setup.py install --root="$pkgdir" --optimize=1
+ rm -r "$pkgdir"/usr/lib/python*/site-packages/tests/
+}
Property changes on: python-pykeepass/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list