[arch-commits] Commit in adriconf (3 files)

[Balló György]

    Date: Sunday, December 16, 2018 @ 23:06:56
  Author: bgyorgy
Revision: 416472

archrelease: copy trunk to community-x86_64

Added:
  adriconf/repos/
  adriconf/repos/community-x86_64/
  adriconf/repos/community-x86_64/PKGBUILD
    (from rev 416471, adriconf/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: adriconf/repos/community-x86_64/PKGBUILD (from rev 416471, adriconf/trunk/PKGBUILD)
===================================================================
--- repos/community-x86_64/PKGBUILD	                        (rev 0)
+++ repos/community-x86_64/PKGBUILD	2018-12-16 23:06:56 UTC (rev 416472)
@@ -0,0 +1,40 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=adriconf
+pkgver=1.3
+pkgrel=3
+pkgdesc="GUI tool to configure Mesa drivers by setting options and writing them to the standard drirc file"
+arch=(x86_64)
+url="https://github.com/jlHertel/adriconf"
+license=(GPL3)
+depends=(boost-libs gtkmm3 libxml++2.6 pciutils)
+makedepends=(boost cmake git gtest)
+_commit=93e4ac64999c3ef3f73aab593cca642ef1d9da6f  # tags/v1.3
+source=("git+https://github.com/jlHertel/adriconf#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname \
+    -DCMAKE_INSTALL_PREFIX=/usr
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  cd ../$pkgname
+  install -Dm644 flatpak/br.com.jeanhertel.adriconf.appdata.xml "$pkgdir/usr/share/metainfo/br.com.jeanhertel.adriconf.appdata.xml"
+  install -Dm644 flatpak/br.com.jeanhertel.adriconf.desktop "$pkgdir/usr/share/applications/br.com.jeanhertel.adriconf.desktop"
+  install -Dm644 flatpak/br.com.jeanhertel.adriconf.png "$pkgdir/usr/share/icons/hicolor/256x256/apps/br.com.jeanhertel.adriconf.png"
+}