[arch-commits] Commit in lib32-libpng/repos (2 files)
Christian Hesse
eworm at archlinux.org
Thu Dec 20 08:04:41 UTC 2018
Date: Thursday, December 20, 2018 @ 08:04:41
Author: eworm
Revision: 416875
archrelease: copy trunk to multilib-testing-x86_64
Added:
lib32-libpng/repos/multilib-testing-x86_64/
lib32-libpng/repos/multilib-testing-x86_64/PKGBUILD
(from rev 416874, lib32-libpng/trunk/PKGBUILD)
----------+
PKGBUILD | 53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 53 insertions(+)
Copied: lib32-libpng/repos/multilib-testing-x86_64/PKGBUILD (from rev 416874, lib32-libpng/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD (rev 0)
+++ multilib-testing-x86_64/PKGBUILD 2018-12-20 08:04:41 UTC (rev 416875)
@@ -0,0 +1,53 @@
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Contributor: dorphell <dorphell at archlinux.org>
+# Contributor: Travis Willard <travis at archlinux.org>
+# Contributor: Douglas Soares de Andrade <douglas at archlinux.org>
+
+_pkgbasename=libpng
+pkgname=lib32-$_pkgbasename
+pkgver=1.6.36
+_apngver=1.6.36
+_libversion=16
+pkgrel=1
+pkgdesc="A collection of routines used to create PNG format graphics files (32-bit)"
+arch=('x86_64')
+url="http://www.libpng.org/pub/png/libpng.html"
+license=('custom')
+depends=('lib32-zlib' $_pkgbasename)
+makedepends=(gcc-multilib)
+source=("https://downloads.sourceforge.net/sourceforge/${_pkgbasename}/${_pkgbasename}-${pkgver}.tar.xz"
+ "https://downloads.sourceforge.net/sourceforge/libpng-apng/libpng-${_apngver}-apng.patch.gz")
+sha256sums=('eceb924c1fa6b79172fdfd008d335f0e59172a86a66481e09d4089df872aa319'
+ '8c1f33da739b29a77e35e5a1ebcdffaab63bfe184be8b5a97677cc80156fdc0f')
+
+build() {
+ export CC="gcc -m32"
+ export CXX="g++ -m32"
+ export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+ cd "${srcdir}/${_pkgbasename}-${pkgver}"
+
+ # Add animated PNG (apng) support
+ # see http://sourceforge.net/projects/libpng-apng/
+ patch -p1 -i "${srcdir}/libpng-${_apngver}-apng.patch"
+
+ ./configure --prefix=/usr --libdir=/usr/lib32 --program-suffix=-32 --disable-static
+ make
+}
+
+package() {
+ cd "${srcdir}/${_pkgbasename}-${pkgver}"
+
+ make DESTDIR="${pkgdir}" install
+
+ cd contrib/pngminus
+ make PNGLIB="-L${pkgdir}/usr/lib32 -lpng" -f makefile.std png2pnm pnm2png
+
+ rm -rf "${pkgdir}"/usr/{include,share}
+
+ rm "$pkgdir/usr/bin/libpng-config"
+ ln -s "libpng${_libversion}-config-32" "$pkgdir/usr/bin/libpng-config-32"
+
+ mkdir -p "$pkgdir/usr/share/licenses"
+ ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
+}
More information about the arch-commits
mailing list