[arch-commits] Commit in haskell-http-client/repos (2 files)

[Felix Yan]

    Date: Tuesday, December 25, 2018 @ 11:09:10
  Author: felixonmars
Revision: 417914

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-http-client/repos/community-staging-x86_64/
  haskell-http-client/repos/community-staging-x86_64/PKGBUILD
    (from rev 417913, haskell-http-client/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-http-client/repos/community-staging-x86_64/PKGBUILD (from rev 417913, haskell-http-client/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-12-25 11:09:10 UTC (rev 417914)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=http-client
+pkgname=haskell-http-client
+pkgver=0.5.14
+pkgrel=4
+pkgdesc="An HTTP client engine"
+url="https://github.com/snoyberg/http-client"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-blaze-builder' 'haskell-case-insensitive' 'haskell-cookie'
+         'haskell-exceptions' 'haskell-http-types' 'haskell-memory' 'haskell-mime-types'
+         'haskell-network' 'haskell-network-uri' 'haskell-random' 'haskell-streaming-commons'
+        )
+makedepends=('ghc' 'haskell-async' 'haskell-hspec' 'haskell-monad-control' 'haskell-zlib')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('bf4a42572da5d5711e5feb4c8c285fafebe8563ae3b4eadba02a8f3d54fb33a1c1bf1085e9b2531ee9218151211910b4df9a0d8eb8dc73502c79f7db3be34ff9')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid -fnetwork-uri
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}