[arch-commits] Commit in haskell-servant/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sun Dec 30 11:18:59 UTC 2018


    Date: Sunday, December 30, 2018 @ 11:18:59
  Author: felixonmars
Revision: 419117

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-servant/repos/community-staging-x86_64/
  haskell-servant/repos/community-staging-x86_64/PKGBUILD
    (from rev 419116, haskell-servant/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: haskell-servant/repos/community-staging-x86_64/PKGBUILD (from rev 419116, haskell-servant/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-12-30 11:18:59 UTC (rev 419117)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=servant
+pkgname=haskell-servant
+pkgver=0.14.1
+pkgrel=4
+pkgdesc="A family of combinators for defining webservices APIs"
+url="http://haskell-servant.readthedocs.org/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-compat' 'haskell-aeson' 'haskell-attoparsec'
+         'haskell-case-insensitive' 'haskell-http-api-data' 'haskell-http-media'
+         'haskell-http-types' 'haskell-natural-transformation' 'haskell-mmorph'
+         'haskell-tagged' 'haskell-singleton-bool' 'haskell-string-conversions'
+         'haskell-network-uri' 'haskell-vault')
+makedepends=('ghc' 'haskell-cabal-doctest' 'haskell-aeson-compat' 'haskell-hspec'
+             'haskell-quickcheck' 'haskell-quickcheck-instances' 'haskell-doctest')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('a767a41c4682cfd3c52fca0c55862b9ce2d008fc388a44946621dbd67fa4d30b6f1d2c18642e410a58fadd2d26299bf67192a5def7f6d18afff18da284a44569')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *4.12/<5/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


More information about the arch-commits mailing list